OK I like to know how things work so although you can and probably should do this with a module here is how you roll your own (without even needing recursion)

#!/usr/bin/perl -w

use strict;

my $root  = 'c:/winnt/';
my @dirs  = ($root);
my @files;

for my $path (@dirs){
    opendir ( DIR, $path ) or next;   # skip dirs we can't read
    while (my $file = readdir DIR) {
      next if $file eq '.' or $file eq '..'; # skip dot files
      next if -l $path.$file;                # skip sym links
        if ( -d $path.$file ) {
            push @dirs, $path.$file.'/';     # add dir to list
        } 
        else {
            push @files, $path.$file;        # add file to list  
        }     
    }
    closedir DIR;
}

print "Directory list\n\n";
print "$_\n" for sort @dirs;

print "\n\nFile List\n\n";
print "$_\n" for sort @files;
[download]

How we do it is simple. First we define our root dir and our delimiter and push this into the @dirs array. We then iterate over the @dirs array. Although @dirs initially only contains the root dir we find all its subdirs and push them onto the end of this. Thus after the first iteration @dirs contains all the subdirs of our root dir which we then search for subdirs and so on ad infinitum until we have no more subdirs. Testing for the . and .. dirs is important as these are the current and one level up dirs. We do not want to follow symbolic links otherwise we may end up in an infinite loop.

We then test each 'file' to see if it is a direcory or a file and push it into the appropriate array. By the fime we have iterated over @dirs we have root and all it subdirectories (to whatever depth) in @dirs and all the files in @files. These are the fully qualified paths.

Hope this helps.

cheers

tachyon

s&&rsenoyhcatreve&&&s&n.+t&"$'$`$\"$\&"&ee&&y&srve&&d&&print

use strict;

my @dirs = system(dir /b /s);

for (@dirs)  {print;}
[download]

The system function returns the exit status code of the program, not its output. See system and the qx or backticks operator. More importantly, your code will only run on Win32, whereas File::Find will work on Unix and related systems as well.

There is an issue with File::Find (and hand-rolled solutions too) on win32 when working with mapped file systems. It will stat every file to determine whether it is a directory and needs to be recursed into. Each stat requires a server round-trip which can be slow.

If you call the DOS function you can do the whole thing in one hit. If you are certain the script will never be needed on a non-win32 system there is no issue with portability.

I was doing something similar a while back, and reduced the run time from several hours to under ten minutes.

-- iakobski

You might better want to use backticks or pipe-open instead of system to get the output on STDOUT...

e.g backticks


my @files = `dir /b /s`;
chomp(@files);
[download]

or with pipe-open:

unless (open (DIR, "dir /b /s |")){
  die "Error: couldn't execute dir-command: $!\n";
}
else {
  my @files = <DIR>;
  close (DIR);
  chomp(@files);
}
[download]

Best regards,
perl -le "s==*F=e=>y~\*martinF~stronat~=>s~[^\w]~~g=>chop,print"