use Socket;
use IO::Handle;
$host="www.google.com";
socket(S,PF_INET,SOCK_STREAM,0);
S->autoflush(1);
$s=sockaddr_in(80,inet_aton($host));
if (connect(S,$s)) {
  print "connected to $host\n";
  print S "GET \/ HTTP\/1.0\n\n";
  read(S,$data,100) || die;
  close(S);
} else { die "connect failed\n" }

print $data;
[download]

use strict;
use Socket;
use IO::Handle;

my $data;
my $port = 80;
my $host = inet_aton('www.google.com') or die 'unkown host';
my $protocol = getprotobyname('tcp');

socket(SOCK,AF_INET,SOCK_STREAM,$protocol) or die "socket failed: $!";
my $dest_addr = sockaddr_in($port,$host);

connect(SOCK,$dest_addr) or die "connect failed: $!";

print STDERR "connected to host\n";
print SOCK "GET / HTTP/1.0\n\n";

SOCK->autoflush(1);
read(SOCK,$data,100);
close(SOCK);

print $data;
[download]

use strict;
use IO::Socket;

my $data;
my $port = 80;
my $host = 'www.google.com';

my $socket = IO::Socket::INET->new(
   Proto => 'tcp',
   PeerAddr => $host,
   PeerPort => $port,
) or die "socket failed: $@";

$socket->autoflush(1);

print STDERR "connected to host\n";
print $socket "GET / HTTP/1.0\n\n";

$socket->recv($data,100);

print $data;
[download]

jeffa

L-LL-L--L-LL-L--L-LL-L--
-R--R-RR-R--R-RR-R--R-RR
B--B--B--B--B--B--B--B--
H---H---H---H---H---H---
(the triplet paradiddle with high-hat)

Where is your debugging code? I mean: perl gives you all the means of tracking down the errors, yet I don't see you used any of them. Let me explain:

• You need to put #!/usr/bin/perl -w in the first line to get warnings.
• You should use strict.
• You should always check return values.
• When an error occurs, print out the error (using $!):

  if (connect(S,$s)) {
    print "connected to $host\n";
    print S "GET \/ HTTP\/1.0\n\n";
    read(S,$data,100) || die "Error Reading: $!\n";
    close(S);
  } else { die "connect failed: $!\n" }
  [download]

• Read the perldocs carefully as the socket function clearly states: You should "use Socket", and the read page states: Returns the number of bytes actually read, 0 at end of file, or undef if there was an error. . So, at the read line, you should do my $lines = read(...); die "Error Reading: $! \n" unless defined $lines;
• Check out the LWP and LWP::Simple for doing HTTP get, and save yourself the headache.
• If you really want to do raw protocol level communication, then use the IO::Socket::INET for a clearer more OO interface to sockets.