If you're sure that - or some other delimeter will always be present and in the same position, split would suit your example...

 # left = 555, right = 4587
my($left,$right) = split( /-/ => $string, 2 );
[download]

If you really wanted only the first three regardless of content, then take a look at substr...

 # left = 555, string = 555-4587
my($left) = substr( $string => 0, 3 );

 # leftmost = 555, string = -4587
my($left) = substr( $string => 0, 3, "" );
[download]

    --k.

Please do not use arrow as a synonym for comma except in the privacy of your own cubicle. Otherwise, in the most general case, it can lead to breakage. Witness:

@things = split /,/ => $input; # works
use constant DELIMITER => ',';
@things = split DELIMITER => $input; # BREAKS (treats DELIMITER as a q
+uoted word)
@things = split DELIMITER, $input; # works
[download]

Fat arrow should be used only when the quoting powers are wanted, and possibly to set up hash key/value pairs, paying special care to in-scope "use constants".

-- Randal L. Schwartz, Perl hacker

my $phone = "555-4587";
$phone =~ /(\d\d\d)/;
my $first_three = $1;
[download]

Joshua

You can combine the last two lines:

my ($first_three) = $phone =~ /(\d{3})/;
[download]

jeffa

L-LL-L--L-LL-L--L-LL-L--
-R--R-RR-R--R-RR-R--R-RR
B--B--B--B--B--B--B--B--
H---H---H---H---H---H---
(the triplet paradiddle with high-hat)

Egads! A regex where substr would suffice! Shame, shame!

Update: OK, this was a good-natured jest but it seems at least a few people take issue with my above remark. So, anyway, here is some data to backup my comment. First of all, the poster asked specifically how to find the leftmost three characters of a string. His example showed a number (presumably a phone number) but the title of the post did not limit the problem domain to phone numbers. The poster asked for "the three leftmost characters" and the answer given was "the first three digits" which are not the same thing -- hence my good natured jest. This is a perfect problem for substr. Sure, the regex works fine, but it's overkill. It's like pulling out a chainsaw when all you need is a butter knife. substr is also more than twice as fast.

regex: 37.940104 seconds
substr: 14.430599 seconds
[download]

The benchmark code that produced the above results is:

#!/usr/bin/perl

use strict;
use warnings;
use Time::HiRes qw/ gettimeofday tv_interval /;

#load up the numbers
open my $fh, "< nums.out" or die;
my @numbers = <$fh>;
my $first_three;
my ($start, $stop, $run_time);

my $count = 100;

$start = [gettimeofday()];
for (0..$count)
{
    foreach my $phone (@numbers) 
    {
        ($first_three) = $phone =~ /(\d{3})/;
    }
}
$stop = [gettimeofday()];
$run_time = tv_interval($start,$stop);
print "regex: $run_time seconds\n";

$start = [gettimeofday()];
for (0..$count)
{
    foreach my $phone (@numbers) 
    {
        $first_three = substr $phone, 0, 3;
    }
}
$stop = [gettimeofday()];
$run_time = tv_interval($start,$stop);
print "substr: $run_time seconds\n";
[download]

I didn't use Benchmark because it didn't like it when I tried to pre-load the numbers (it's a file of 10,000 strings that match the poster's example). I wanted to pre-load to avoid file I/O messing up the benchmark.

substr $str, 0, 3;

Abigail