#!/usr/bin/perl

use strict;
use warnings 'all';

my @arr1 = map {[split //]} <DATA>;
my @arr2 = map {my $n = $_; join "" => map {$_ -> [$n]} @arr1}
           0 .. @{$arr1 [0]} - 2;

print "$_\n" for @arr2;

__DATA__
ABC
DBC
ECC
FFF
[download]

ADEF
BBCF
CCCF

Abigail

use strict;
use warnings;
my @list=map{chomp;$_}<DATA>;
my @output;
foreach my $line (@list) {
  foreach my $ofs (0..length($line)-1) {
    $output[$ofs].=substr($line,$ofs,1);
  }
}
print join ("\n",@output),"\n";
__DATA__
ABC
DEF
GHI
JKL
MNO
PQR
STU
[download]

ADGJMPS
BEHKNQT
CFILORU

Yves / DeMerphq
---
Writing a good benchmark isnt as easy as it might look.

use Data::Dumper;

my @array;
# read from the file handle line by line
while(<DATA>) {
  chomp;

  # split each line by ',' and save
  # corresponding records into the @recs array
  my @recs = split /\,/;

  # loop through the records array..
  for (my $i; $i < @recs; $i++) {

    # and save I-th record in array
    # array[I].  Use @{..} to let push() know
    # that array[I] is also an array.
    push @{$array[$i]}, $recs[$i];
  }
}

print Dumper(\@array);

__DATA__
A,B,C
D,B,C

E,C,C
[download]

$VAR1 = [
          [
            'A',
            'D',
            'E'
          ],
          [
            'B',
            'B',
            'C'
          ],
          [
            'C',
            'C',
            'C'
          ]
        ];
[download]

open(I,$0);<I>;$~=$/;$/='~';$_=<I>;($/)=/(.)$~/;s/[$~~]//g;/(v)/;$-=$-[0];s;\Q$/\E;$~;g;($/,$^)=/^(.)(.)/;
#%  xxxxxx   xx-+  xx    xxx xx  xx       xx  xx   xxx   xxxxx+ xx  xx xxxx xxxxx  ......+
#x xxxxvxxx xx  xx xv   xxxx x+ %+  ===== xx  xx  xx xx  x+  =x xx xx  xx   xx xx ...+
#x xx xx xx xx  xx xx  xx xx xxx+         xxxxxx xx   +x xx     xx+x-  xxxx xxxx ........+
#% xx xx xx xx  xx xx xx  x+ xx xx  =+=== xx  xx xxxx-xx xx  =x +x xx  xx   xx xx ...+
#% xx xx xx  -+x+  xxx+   xx xx  xx       xx  xx x+   xx xxx+xx xx  xx xxxx xx  xx ....+~
for(split/$~/){s,[ $/],,g;/(.)$/;$l=$-[0];/(.)/||next;$_=chr$-+$l;$".=($1=~/$^/)?" \u$_":$_;}print$";

Since this smells of homework, I'll be brief. You'll need a split and a loop, and to do an append, if you want the first element to contain everything in the first columm, etc. That much should lead you to the answer, with some thought.

Failing that, I am adding an additional hint from a CB discussion with broquaint, but try this for yourself first-you will gain more from the thought involved than you may realize.

split the string char for char, then append it to the array with its position.... as long as all strings are the same length.... hrm...

How about something along the lines of:

#!/usr/bin/perl

use Data::Dumper;

while (<DATA>) {

  my $i=0;

  for $c (/./g) {

    push (@{$array[$i++]}, $c);
  }
}

print Dumper(\@array);

__DATA__
ABC
DBC
ECC
[download]

--
Steve Marvell

#!/usr/local/bin/perl
use Data::Dumper;
map{(/\n/)?$i=0*$j++:$r[$i++][$j]=$_;}split // while(<DATA>);

print Dumper(\@r);


__DATA__
ABC
DBC
ECC
[download]

Update 2:
map{(/\n/)?$i=0*$j++:$r[$i++][$j]=$_;}split//for<DATA>;