Syntax errors from the absence of commas between lists, and a surprise from trying to dimension the array. You are assigning to one element of the array.

A multidimensional array in Perl is a one-dimensional array of references to arrays. What you mean to write is:

my @a = (
           [' ',' ',' ','#','#','#',' ',' ',' '],
           [' ',' ','#','#',' ','#','#',' ',' '[,
           [' ','#','#',' ',' ',' ','#','#',' '],
           ['#','#',' ',' ',' ',' ',' ','#','#'],
           ['#','#','#','#','#','#','#','#','#'],
           ['#','#',' ',' ',' ',' ',' ','#','#'],
           ['#','#',' ',' ',' ',' ',' ','#','#']
        );
[download]

What's wrong with this?

Just that Perl often Does What You Mean, doesn't mean you can just go try syntaxes you already know from other languages. If you want to do something you haven't done in Perl before, you should read documentation, because code like this is very unlikely to work. I suggeset you read the following documents:

• perllol
• perlreftut
• perlref
• perlsyn

Your code doesn't work for several reasons.

• Arrays are sized automatically in Perl, so with $foo[4], you're already using the fifth element of @foo. With $foo[4][8], you're using the ninth element of the array that is referenced to in the fifth element of @foo. To assign to @foo, use @foo.
• Anonymous array references are made with square brackets, not curlies. Perl does not have multidimentional arrays natively, but it can have arrays that hold references to other arrays. When not naming them, they are anonymous.
• Elements need to be separated with commas.

@foo = (
    [1, 2, 3],
    [4, 5, 6],
    [7, 8, 9]
);
print $foo[2][1]; # prints 8
[download]

- Yes, I reinvent wheels.
- Spam: Visit eurotraQ.

#!/usr/bin/perl -w

$a = [
   [' ',' ',' ','#','#','#',' ',' ',' '],
   [' ',' ','#','#',' ','#','#',' ',' '],
   [' ','#','#',' ',' ',' ','#','#',' '],
   ['#','#',' ',' ',' ',' ',' ','#','#'],
   ['#','#','#','#','#','#','#','#','#'],
   ['#','#',' ',' ',' ',' ',' ','#','#'],
   ['#','#',' ',' ',' ',' ',' ','#','#']
     ];
print "$a->[4][0]\n";
[download]

That is, of course, if you can live with the idea of changing spaces to dots. Consider:

my @a = (
  [qw/. . . # # # . . ./],
  [qw/. . # # . # # . ./],
  [qw/. # # . . . # # ./],
  [qw/# # . . . . . # #/],
  [qw/# # # # # # # # #/],
  [qw/# # . . . . . # #/],
  [qw/# # . . . . . # #/],
);
[download]

Of course, if you really do need spaces instead of dots in your array entry, you shall have to map the dots back to spaces:

my @a = (
  [map{tr/./ /;$_} qw/. . . # # # . . ./],
  [map{tr/./ /;$_} qw/. . # # . # # . ./],
  [map{tr/./ /;$_} qw/. # # . . . # # ./],
  [map{tr/./ /;$_} qw/# # . . . . . # #/],
  [map{tr/./ /;$_} qw/# # # # # # # # #/],
  [map{tr/./ /;$_} qw/# # . . . . . # #/],
  [map{tr/./ /;$_} qw/# # . . . . . # #/],
);
[download]

Then again, that still looks too stretched out to help you easily comprehend what's in the array. And it's not really much simpler than what you had initially. Better, then, to use a different approach, this time using split.

my @a = (
  [split //, q/   ###   /],
  [split //, q/  ## ##  /],
  [split //, q/ ##   ## /],
  [split //, q/##     ##/],
  [split //, q/#########/],
  [split //, q/##     ##/],
  [split //, q/##     ##/],
);
[download]

As an added bonus, this way we get our spaces back. Short, sharp and sweet.

By the way, get into the habit of adding a trailing comma on the last element of an array. Perl will silently ignore it, and it really comes in handy when you decide to add to or remove the last array element. Basically, you just don't have to worry any more, and it gives all the lines a pleasing symmetry.