sub first (&@) {
  my $code = shift;

  foreach (@_) {
    return $_ if &{$code}();
  }

  undef;
}
[download]

# first defined value in @list
$foo = first { defined($_) } @list;
[download]

Thank you both. I've found the relevant sections now in perlsub and in the Camel book. For the record, it was as easy as:

sub each_item (&@)
{
    my $test = shift ;
    foreach ( @_ ) { return 0 unless ( eval &$test ) }
    return 1 ;
}
[download]

Thanks again.

Update: On reading kvale's node a little closer, I tried changing my code to:

sub each_item (&@)
{
    my $test = shift ;
    foreach ( @_ ) { return 0 unless &{$test} }
    return 1 ;
}
[download]

...which also worked. Is there any advantage/disadvantage to this over eval?

..which also worked. Is there any advantage/disadvantage to this over eval?

The eval version probably isn't doing what you want, unless you are doing something deliciously perverse. I think your original code is doing this:

# "$x = eval &$foo" becomes:
my $tmp = &$foo(@_);
$x = eval $tmp;
[download]

So you're passing @_ to the user's block, then eval'ing the result. This ends up working because the block presumably accesses $_ directly, and returns an integer (which evals as itself). But it's an ... interesting way to get the job done. An optimist would say that the eval version is "very general".

/s

Among those two calls of &$test they are almost equivalent, and first one will trap any errors, so you can later check $@ variable to see if subroutine died. Like "try" in C++.

OTOH my personal preference is to call anonymous sub as

$test->();
$test->('arg1',$arg2);
[download]

Courage, the Cowardly Dog.
PS. Something fishy is going on there, or my name is Vadim Konovalov. And it's not.

-- 
Joost       downtime n. The period during which a system
            is error-free and immune from user input.
[download]

if (grep {$_->price <= 1000} @product_list) {
    # do stuff
}
[download]

--

flounder

Hey, good idea! Except, to work the same as my example, it needs to be:

if ( ( grep { $_->price <= 1000 } @product_list  ) == @product_list )
{
    # do stuff
}
[download]


_______________
D a m n D i r t y A p e
Home Node | Email

Why so complicated? :)

if(not grep { $_->price > 1000 } @product_list) {
    # do stuff
}
[download]

Update:

my @p = (0,2,4,5,2,5,7,7);
print "1: none\n" if not grep { $_ > 1000 } @p;
push @p, 1002;
print "2: none\n" if not grep { $_ > 1000 } @p;

=output
1: none
[download]

____________
Makeshifts last the longest.

You are right. In my example the { #do stuff } block will get executed if any of the members of @product_list pass the conditions. You want to know if all members pass.

IIRC won't perl6 have some kind of any and all builtins?

--

flounder