in reply to Strip HTML tags again

This problem looks tailor-made for my HTML::TokeParser::Simple module, when combined with HTML::Tagset. The following test will demonstrate:

#!/usr/bin/perl -w
use strict;
use HTML::TokeParser::Simple;
use HTML::Tagset;

my $html = <<'END_HTML';
<a href="mylink">text1</a>
<this is normal text>
END_HTML

my $p = HTML::TokeParser::Simple->new( \$html );

while ( my $token = $p->get_token ) {
    next if ! $token->is_text 
              and 
              exists $HTML::Tagset::isKnown{ $token->return_tag };
    print $token->return_text;
}

[download]

Result:

text1
<this is normal text>

Cheers,
Ovid

Join the Perlmonks Setiathome Group or just click on the the link and check out our stats.

Replies are listed 'Best First'.
Re^2: Strip HTML tags again
by Your Mother (Archbishop) on Mar 05, 2009 at 01:02 UTC

    ++ for the original. I'm posting an updated example because some changes to the module seem to have borked your example. This is an in place stripper--based on the one you posted--with the newer/working syntax. 

    sub strip_html {
    my $renew = "";
    my $p = HTML::TokeParser::Simple->new(\$_[0]);
    no warnings "uninitialized";
    while ( my $token = $p->get_token ) {
        next if ! $token->is_text
            and
            exists $HTML::Tagset::isKnown{ $token->get_tag };
        $renew .= $token->as_is;
    }
    $_[0] = $renew;
}

    [download]
[reply]
[d/l]

In Section Seekers of Perl Wisdom