Does perl -p -i.bak -e "s/^\s+//g" filename not do it (also giving a backup file named filename.bak)?

You open the same file twice. The open to write will clobber the file, so it's empty when it's read.

Instead, open a new filename to write, and rename it after you're done.

After Compline,
Zaxo

{
  local $^I = ".bak";
  local *ARGV;
  @ARGV = "test.txt";
  while (<>) {
    s/^\s+//;
    print;
  }
}
[download]

--
my $chainsaw = 'Perl';

An alternative:

use Tie::File;
tie @file, 'Tie::File', 'test.txt';
s/^\s+// for @file;
[download]

The easiest solution was already mentioned:

perl -i -pe's/^\s+//' test.txt
[download]

- Yes, I reinvent wheels.
- Spam: Visit eurotraQ.

#!/usr/bin/perl -w
use strict;
use fatal;
use File::Copy;

open( FH, "<test.txt" );
open( FH2, ">test.txt.tmp" );

while ( <FH> )
{
  s/^(\s+)//g;
  print FH2 $_;
}
close FH;
close FH2;
move("test.txt.tmp", "test.txt");
[download]

PS. check out perldoc perlrun to learn how to do this in one line.

update: atcroft, runrig and Zaxo: are you guys on a race or something?

test.txt:

0
 1
  2
   3
[download]

test.pl:

#!/usr/bin/perl
use strict;
use warnings;
open(FH, "<", "test.txt");
open(FH2, ">", "test2.txt" );
while(<FH>) {
  s/^(\s+)//g;
  print FH2 $_;
}
close FH2;
close FH;
[download]

test2.pl:

#!/usr/bin/perl
use strict;
use warnings;
open(FH, "<", "test.txt");
my @file = <FH>;
close(FH);
open(FH, ">", "test.txt" );
foreach (@file) {
  s/^(\s+)//g;
  print FH $_;
}
close FH;
[download]

I'm sure there are more ways to do this...

Update: man, I guess I was a little slow to type. When I started the reply, there was only the original node.

My thoughts are mine and mine alone.
They did not originate with the voices in my head.
Do not listen to what they say, it's all lies.