in reply to Random Tips on Parse::RecDescent

Useful compilation, but you can go back and reenable strict 'refs'. 
#!/usr/bin/perl -w
use strict;

for (qw(foo bar)) {
        ($main::{$_} or sub { print "No such sub: $_\n" })->();
}

sub foo {
        print "Yes, I'm here.\n";
}
__END__
Yes, I'm here.
No such sub: bar

[download]
Alternatively: (UNIVERSAL::can('main', $sub) or sub { print "No such sub: $_\n" })->(); ____________
Makeshifts last the longest.

Replies are listed 'Best First'.
Re: Re: Random Tips on Parse::RecDescent
by hsmyers (Canon) on Jul 12, 2002 at 13:21 UTC
    Ok, I'll bite... 
    #!/perl/bin/perl
#
#  coderefs.pl -- Yes you can use strict...
use strict;
use warnings;
use diagnostics;

for (qw(foo bar)) {
        ($main::{$_} or sub { print "No such sub: $_\n" })->();
}
$_ = 'baz';
$main::{$_}(); # works! but,
&{$_}(); # doesn't...

sub foo {
        print "Yes, I'm here.\n";
}

sub baz {
        print "I'm here as well.\n";
}
__END__

    [download]
    So my question is why?

    –hsm

    "Never try to teach a pig to sing…it wastes your time and it annoys the pig."
[reply]
[d/l]

      Because %PACKAGE:: is a special hashtable containing all global symbols from the given PACKAGE. Via that hash, a hard reference to the desired subroutine can be looked up. The call to UNIVERSAL::can produces the same result. And obviously calling a subroutine by dereferencing a hard reference is allowed under the stricture.

      Try the following sometime:

      $ perl -MData::Dumper -e'print Dumper(\%main::);'

      It's rather interesting to poke around in there.

      Basically, a lot of things in Perl (all of OO really, f.ex) are symbolic lookups, so they cannot be evil by nature. What is evil is accidentally using symbolic lookups where you meant a hard dereference. If your code has a bug so that it happens to put a string rather than the hard reference you intended into $var, without the stricture $$var will still work but suddenly becomes a soft reference. If that only happens sporadically, the resulting bugs can be incredibly hard to spot. That's what strict 'refs' catches, and that's why I strongly suggest you reenable it. You're depriving yourself of a very important safety net otherwise.

      Conversly, when you really do need a symbolic lookup, you can still achieve it in ways strict won't complain about. It's just that you explicitly spell out that you do in fact want a symbolic lookup and are fully aware that it's happening.

      Makeshifts last the longest.

[reply]
[d/l]
        Excellent! Good explanation, better idea. The qualification using $main:: becomes Perl's "What I tell you three times is true."-- even better since you don't have to tell it the first two times! Conceptually not greatly different from a 'C' cast. Thanks, it will be in the revised version, I am holding off until Monday or so, hoping for additional useful suggestions...

        –hsm

        "Never try to teach a pig to sing…it wastes your time and it annoys the pig."
[reply]

In Section Meditations