Abigail

Supplementary to Abigail-II's advice here's example code of how you might insert a line into the beginning of a file using Tie::File

use strict;
use Tie::File;

tie(my @fl, 'Tie::File', 'somefile.txt') or die("ack - $!");
unshift @fl, 'a line of text here';
untie @fl;
[download]

If you're not doing line-based insertion into your file then your best choice is to open a new file and write to that.
HTH

_________
broquaint

When using Tie::File, I get the following error: Can't locate Tie/File.pm Is this because I don't have the latest version of Perl?

    #!/usr/bin/perl -w

    use strict;

    # Open the file in read mode
    open  FILE, "file.txt" or die "Error message here $!";

    # Slurp in the file
    my $str = do{local $/; <FILE>};

    close FILE or die "Error message here $!";

    # Reopen the file in write mode (clobbers old file)
    open  FILE, ">file.txt" or die "Error message here $!";

    # Add some text
    print FILE "Prepend this text.\n";

    # Add the old contents of the file.
    print FILE $str;

    close FILE or die "Error message here $!";
[download]

    #!/usr/bin/perl -w

    use strict;

    # Open the file for reading and writing
    open  FILE, "+<file.txt" or die "Error message here $!";

    # Slurp in the file
    my $str = do{local $/; <FILE>};

    # Rewind the file
    seek FILE, 0, 0;

    # Add some text
    print FILE "Prepend this text.\n";

    # Add the old contents of the file.
    print FILE $str;

    close FILE or die "Error message here $!";
[download]

Both of these examples assume that the data in the file isn't too large to be slurped into memory. If it is then you can modify the code to use an intermediary file.

--
John.

#!/usr/bin/perl

open INFILE, "<infile";
open OUTFILE, ">tmpfile";    # Create your temporary names with care, 
+or die a painful race-condition death.

print OUTFILE qq!Here you print the new stuff.
...
!;

while (<INFILE>) {
 print OUTFILE $_;
}

close INFILE;
close OUTFILE;
[download]

I mentioned this before here.

This will add text to the beginning of temp.txt and back up the current contents of temp.txt to temp.txt.bak

perl  -pi.bak -e 'unless ($notfirst++){print "text to add\n";}' temp.t
+xt
[download]

--

flounder

#!/usr/bin/perl
$file= $ARGV[0];
@file =(<>);
unshift @file, "My newline headline\n";
open (FH,">$file")or die "Cant open: $!";
print FH @file;
close FH;
[download]