Abigail

You're right, there are many ways to break something like this, but I was just thinking of something for the common case: sub foo appears, but a call to foo(...) doesn't appear in the same package. That's what I was trying to say with "it doesn't have to be bulletproof".

I guess an analogy would be perltidy. It can be thrown off without trying very hard, but in the common cases it can be helpful.

Given that both OO modules and exporting modules are very common, the case of having sub foo appear in a package without a call to it is indeed common. It's also not an unused sub.

Abigail

Looks like you should be able to use Devel::DProf to check for dead subroutines in the same way you'd check for hot-spot subroutines. If you're running automated tests, adding an automated dead-code check shouldn't be too difficult.

--
The hell with paco, vote for Erudil!
:wq

Just an additional note --- 'used only once' won't come into play in a variety of situations:

#!/usr/bin/perl -w
use strict;
use vars qw/$abc @def %ghi/;
our($jkl, @mno, %pqr);
my($stu, @vwx, %y_and_z);
sub qux {}
open(FOO,$0) or die $!;
opendir(DIR, '.') or die $!;
[download]

In 5.6.1, the above throws warnings for FOO and DIR, and all of the our variables, but nothing else --- in 5.8.0, only FOO and DIR elicit warnings. Variables declared with 'use vars' (and now our) are exempt, as are subroutines and lexicals.

To top it off, 'used only once' really only applies to things in the symbol table, and in particular, is elicited only when the *typeglob is used but once --- as soon as two or more slots in a typeglob are filled, all identifiers within that typeglob are exempt:

#!/usr/bin/perl -w
use strict;

use vars '$foo';
our(@foo);       # second use of *foo

$main::bar = 42;
%main::bar = (a => 1);       # second use of *bar

our($FOO, @DIR);
open(FOO,$0) or die $!;      # second use of *FOO
opendir(DIR, '.') or die $!; # second use of *DIR

sub blah {}
our($blah); # second use of *blah
[download]

No warnings --- even though $main::bar is used only once, the *bar identifier is used more than once.

#!/usr/bin/perl
use strict;

my $F = shift || die "no file specified";

my $xref_cmd = "$^X -MO=Xref,-r $F";

my %subdef;
my %subused;

my @fields = qw( file context line package sigil name action );

open TMP, "$xref_cmd |";
# Xref mangles up filenames, so we need to binmode it
binmode TMP;

while(<TMP>) {
    chomp;
    my %data;
    @data{ @fields } = split( /\s+/ );

    if( $data{action} eq "subdef"
    and $data{package} eq "main"
    and $data{file} eq $F
    ) {
        $subdef{ $data{name} } = "$data{file}:$data{line}";
    }

    if( $data{action} eq "subused"
    and $data{package} eq "main"
    and $data{file} eq $F
    ) {
        $subused{ $data{name} } = "$data{file}:$data{line}";
    }

}
close TMP;

foreach my $sub (keys %subdef) {
    next if exists $subused{ $sub };
    print "$subdef{ $sub } $sub\n";
}
[download]

cheers,
Aldo

__END__
$_=q,just perl,,s, , another ,,s,$, hacker,,print;
[download]