#!/usr/local/bin/perl -w
use strict;
open( FH,  "userlist" ) || die "no userlist: $!";
open( FH2, ">output" )  || die "no output file: $!";
while (<FH>) {
    chomp;
    my $file    = ("/usr/home/$_/INBOX");
    my $maxsize = ( 30000 * 1024 );
    if ( -s $file ) {
        my $size = ( stat $file )[7];
        my $meg  = int( $size / 1024000 );
        if ( $size > $maxsize ) {
            printf "%25s %3sMB\n", $_, $meg;
            print FH2 "$_:$meg\n";
        }
    }
}
close(FH)  || die "couldn't close userlist: $!:";
close(FH2) || die "couldn't close output: $!";
[download]

jeffa

L-LL-L--L-LL-L--L-LL-L--
-R--R-RR-R--R-RR-R--R-RR
B--B--B--B--B--B--B--B--
H---H---H---H---H---H---
(the triplet paradiddle with high-hat)

if (-s $file)  {
  my $size = (stat _)[7];
[download]

Well actually, instead of this:

if (-s $file)  {
    my $size = (stat _)[7];
}
[download]

I tend to prefer this:

my $size = ( -s $file );
[download]

because the -s returns the file size in bytes. If you want anything else from stat along with the file size, then check "perldoc -f stat" to recall how stat orders things, and do something like this:

my ($mode,$uid,$size,$modtime) = (stat $file)[2,4,7,9];
[download]

And I agree with Jeffa -- perltidy is a Blessing To Us All, because proper indentation is every programmer's friend.

BTW, slight correction. The multipication is only done once, at compile-time. OTOH, the result doesn't need to be assigned to a variable every time through the loop. In fact, even better, it doesn't need to be assigned to a variable at all; use constant MAXSIZE => 30000*1024 at the top. Even better, 30*1024*1024, which is probably what you meant.

---

Confession: It does an Immortal Body good.

Here's my version; I made some changes that I thought cleaned things up a little:

1. This version uses readdir to get the list of home directories, so you can avoid creating a temporary file with ls first;
2. The output goes to STDOUT only. I think that, since your on a *nix machine, you'll find it advantageous not to send your output to a hard-wired data file. If you want your output to go to the screen and a file simultaneously, use the tee command; eg.

   perl my_script.pl | tee my_logfile.dat
   [download]

3. I know this code rather contradicts the quote in my sig, but I couldn't help it. It was too much fun rebuilding the processing into one line. Sorry.

#! /usr/bin/perl

use strict ;
use warnings ;
$|++ ;

use Data::Dumper ;

my $home_root  = '/usr/home' ;
my $size_limit = 30 * 1_024_000 ;

opendir HOME, $home_root or die "Couldn't open $home_root: $!" ;

printf "%-25s | %3.2fMB\n", $_->[0], $_->[1] / 1_024_000
   for grep { $_->[1] > $size_limit }
       map  { [ $_ => ( stat "$home_root/$_/INBOX" )[7] || 0 ] }
       grep { -d "$home_root/$_" } readdir HOME ;

closedir HOME ;

exit ;

__END__
[download]

Those who know that they are profound strive for clarity. Those who
would like to seem profound to the crowd strive for obscurity.
            --Friedrich Nietzsche

  
if (-s $file)  { 
my $size = (stat $file)[7];
[download]

That would be better written as: my $size = -s $file;

See perlfunc for documentation of the fact that -s returns the size of the file (in bytes.)

Update: (Answering Chmrr's reply below...)

 
my $size = -s $file; 
if ($size) { . . . }
[download]

-sauoq
"My two cents aren't worth a dime.";

Actually, it's probably better written as:

if (my $size = -s $file)

..or, if you don't like the assignment in the if, you can keep the (oh-so-slight..) efficiency increase by saying:

if (-s $file)
  my $size = -s _;
[download]

perl -pe '"I lo*`+$^X$\"$]!$/"=~m%(.*)%s;$_=$1;y^`+*^e v^#$&V"+@( NO CARRIER'