#!/usr/bin/perl
#
# given a file name as an argument,
# read the file until eof, back up
# one line and truncate the file there.
# in short, "delete the last line of a file"
#
my $file=shift(@ARGV);
open(FILE,"+<$file") or die;
while (<FILE>) {
    if (eof(FILE)) {
       seek(FILE,-(length($_)),2) or die;
       truncate(FILE,tell(FILE)) or die;
    }
}
close FILE;
[download]

perl -pi -we '$_="" if eof' your_file
[download]

-- Mike

--
just,my${.02}

Update: see also Delete the last line of a file.

--
John.

I'm trying to run the shell command in my script, but for some reason, it's not working....can anyone pinpoint the problem? thanks

my @args = qw/ perl -i -ne 'print unless eof' filename /;
system(@args) == 0 or die "error with deleting last line";
[download]

I don't think you understand what qw does. Try running this and I think you will figure it out.

my @args = qw/ perl -i -ne 'print unless eof' filename /;
print join "|", @args;
[download]

--

flounder

That was just a one-liner.

If you need to do something more sophisticated as part of a program you should try something like this.

    #!/usr/bin/perl -w

    use strict;

    # Localised in-place edit
    {
        local $^I = ''; # or use '.bak' to save a back-up 
        local @ARGV = 'somefile';

        while (<>) {
            print unless eof;
        }
    }

    __END__
[download]

--
John.

Tip: if you show some code, I bet you would get more results.