#!/usr/local/bin/perl -wd

my $DBS = {DB1=>1,DB2=>1,Q=>1};

my $db = select_db($DBS);

sub select_db {
   my( $dbs ) = shift;
   my( $adb );

   while(1) {
      print "Select a database: ";
      $adb = <STDIN>;
      chomp($adb);
      last if $dbs->{uc $adb};
   }
   $adb;
}
[download]

Since I assume you don't have two databases with the same name, making them hash keys makes the test much easier.

#! /usr/bin/perl

use strict ;
use warnings ;
$|++ ;

my $DB = 0 ;
my %DB_list = map { $_ => 1 } qw( DB1 DB2 ) ;

until ( $DB_list{ $DB } ) {
    print "Select a database: " ;
    chomp( $DB = <STDIN> ) ;
    $DB = uc $DB ;
    if ( $DB eq 'Q' ) { print "Quitting...\n" and exit }
}

print "You chose $DB.\n" ;

__END__
[download]

Those who know that they are profound strive for clarity. Those who
would like to seem profound to the crowd strive for obscurity.
            --Friedrich Nietzsche

use strict;

my $DB;
my @DB = qw(DB1 DB2);

{
   $DB = select_db();
   redo unless grep {$_ eq $DB} (@DB,'Q');
}
   
die if $DB eq 'Q';

sub select_db {
   print "Select a database: ";
   chomp($_ = <STDIN>);
   return $_;
}
[download]

jeffa

L-LL-L--L-LL-L--L-LL-L--
-R--R-RR-R--R-RR-R--R-RR
B--B--B--B--B--B--B--B--
H---H---H---H---H---H---
(the triplet paradiddle with high-hat)

my @valid=qw(DB1 DB2);
do {
  print "Enter a DB choice: ";
  $choice=<STDIN>;
  chomp $choice;
  die if $choice eq 'Q';
} until grep {$_ eq $choice} @valid;
[download]

--
Tommy
Too stupid to live.
Too stubborn to die.

 #! perl -w
 my @dbs = <DATA>; 
 my $db= "\n";

print "Select DB from:\n @dbs or Q to quit:" 
      and $db = uc(<>) 
          while( $db eq "\n" || "@dbs\nQ\n" !~ m/$db/s);
chomp $db;

$db eq 'Q' and die "Quiting...\n";

print "\n$db selected\n";

__DATA__
DB1
DB2
[download]

Looks like this is use:

C:\test>190748
Select DB from:
 DB1
 DB2
 or Q to quit:
Select DB from:
 DB1
 DB2
 or Q to quit:fred
Select DB from:
 DB1
 DB2
 or Q to quit:db2

DB2 selected

C:\test>190748
Select DB from:
 DB1
 DB2
 or Q to quit:q
Quiting...

C:\test>
[download]

That is a thing of beauty. Thank you all for your replies. I've learned quite a bit from this. Brandon