kidd has asked for the wisdom of the Perl Monks concerning the following question:

Hello...

I want to know if there is a way in which I can randomnize(?) the content in an array.

In example:
Lets say I have this array with names:

my @array = ('uriel', 'daniel', 'joel', 'samuel');

[download]

Now what I want is create a process so every time I print the array it prints the names in different order.


I've already tried this without success because it returns a number:

#!/usr/bin/perl -w

use strict;

my @array = ('uriel', 'daniel', 'joel', 'samuel');


print "Array before random: @array\n\n";


my @n_array = rand(@array);

print "Array after random: @n_array";

[download]

I thoght it might work but it doesnt. I hope someone could give me an idea to work this out...

Thanks

Replies are listed 'Best First'.
•Re: Random array sorting
by merlyn (Sage) on Sep 22, 2002 at 15:22 UTC
    The answer's on your own hard drive, in the form of perldoc -q shuffle: 
    Found in /opt/perl/snap/lib/5.8.0/pods/perlfaq4.pod
  How do I shuffle an array randomly?
            If you either have Perl 5.8.0 or later installed, or if yo
+u have
            Scalar-List-Utils 1.03 or later installed, you can say:

                use List::Util 'shuffle';

                    @shuffled = shuffle(@list);

            If not, you can use a Fisher-Yates shuffle.

                sub fisher_yates_shuffle {
                    my $deck = shift;  # $deck is a reference to an ar
+ray
                    my $i = @$deck;
                    while ($i--) {
                        my $j = int rand ($i+1);
                        @$deck[$i,$j] = @$deck[$j,$i];
                    }
                }

                # shuffle my mpeg collection
                #
                my @mpeg = <audio/*/*.mp3>;
                fisher_yates_shuffle( \@mpeg );    # randomize @mpeg i
+n place
                print @mpeg;

            Note that the above implementation shuffles an array in pl
+ace,
            unlike the List::Util::shuffle() which takes a list and re
+turns
            a new shuffled list.

            You've probably seen shuffling algorithms that work using
            splice, randomly picking another element to swap the curre
+nt
            element with

                srand;
                @new = ();
                @old = 1 .. 10;  # just a demo
                while (@old) {
                    push(@new, splice(@old, rand @old, 1));
                }

            This is bad because splice is already O(N), and since you 
+do it
            N times, you just invented a quadratic algorithm; that is,
            O(N**2). This does not scale, although Perl is so efficien
+t that
            you probably won't notice this until you have rather largi
+sh
            arrays.

    [download]

    -- Randal L. Schwartz, Perl hacker

[reply]
[d/l]
    A reply falls below the community's threshold of quality. You may see it by logging in.
Re: Random array sorting
by Aristotle (Chancellor) on Sep 22, 2002 at 15:15 UTC

    See merlyn's reply below.

    sub shuffle {
    my @shuffled;
    push @shuffed, splice(@_, rand(@_), 1) while @_;
    return @shuffled;
}

print shuffle @array;

    [download]

    The splice pulls a random element out of the array, which is pushed onto the new array. Repeat while there are still elements in the list.

    Makeshifts last the longest.

[reply]
[d/l]
Re: Random array sorting
by FloydATC (Deacon) on Apr 03, 2013 at 10:30 UTC
    Before discovering List::Util I used this: 
    sub shuffled {
  my @ordered = @_;
  my @shuffled = ();
  while (@ordered) {
    my $i = int(rand() * @ordered);
    push @shuffled, $ordered[$i];
    splice(@ordered, $i, 1);
  }
  return @shuffled;
}

print join(",", shuffled(1,2,3,4,5)) . "\n";

    [download]

    ...but I don't anymore.

    -- Time flies when you don't know what you're doing
[reply]
[d/l]

Back to Seekers of Perl Wisdom