in reply to Possible unpack modification (or module)

sub funpack {
    my ($template, $source) = @_;
    my @fields;
    push @fields, $2 while $template =~ s/(\D\d+)(\S+)/$1/;
    my $hash = {};
    @$hash{@fields} = unpack $template, $source;
    return $hash
}

my $data = funpack 'A20name A1sex A3age A8salary A12sign', $foo;

[download]
Completely untested, but I just HAD to mention "fun"pack.

By the way, if you want a module that does this, just create it yourself and put it on CPAN. Make your world a better place, and possibly the worlds of others too. 

- Yes, I reinvent wheels.
- Spam: Visit eurotraQ.

Replies are listed 'Best First'.
Re^2: Possible unpack modification (or module)
by Aristotle (Chancellor) on Sep 30, 2002 at 16:30 UTC
    Or, assuming a less ambiguous template format: 
    sub funpack {
    my ($template, $source) = @_;
    my %hash = map { reverse split /:/, $_, 2 } split " ", $template;
    local $" = ' ';
    @hash{keys %hash} = unpack "@{[ values %hash ]}", $source;
    return \%hash;
}

my $data = funpack 'A20:name A1:sex A3:age A8:salary A12:sign', $foo;

    [download]

    (Field names may start with a digit with this data format. I also find it easier on the eye.)

    Update: D'oh. Always test before posting.. Of course the above code doesn't preserve the order of fields, which is crucial.

    sub funpack {
    my ($template, $source) = @_;

    my ($i, @field, @format) = 0;
    push @{ (\@format, \@field)[$i++ & 1] }, $_
        for map /^([^:]+):(.*)/, split " ", $template;

    local $" = " ";
    return { map +(shift(@format) => $_), unpack "@format", $source };
}

my $data = funpack 'A20:name A1:sex A3:age A8:salary A12:sign', $foo;

    [download]

    Makeshifts last the longest.

[reply]
[d/l]
[select]

In Section Meditations