First of all, invert that array into a hash.

my %monthindex; @monthindex{@months} = 0 .. $#months;
[download]

So now, for any 3 character month string with the proper case, $months[$monthindex{$monthname}] will return the original string. That's why I called it inversion: it inverts the function that is the array lookup by index.

With this, you can do a plain stupid direct sort on hash value:

my @sorted = sort { $monthindex{substr $a, 0, 3} <=> $monthindex{subst
+r $b, 0, 3} || $a cmp $b } @files;
[download]

Or you can do a more sofisticated version with a Schwartzian Transform, caching the substr or better still, the monthindex for the file:

my @sorted = map $_->[0],
    sort { $a->[1] <=> $b->[1] || $a->[0] cmp $b->[0] }
    map [ $_, $monthindex{substr $_, 0, 3}],
      @files;
[download]

In general, I think it would be smarter to do the month lookup for unified case, like all lower case, so you can just as well sort "sep", "Sep", or "SEP".

my @months = qw(jan feb mar apr may jun jul aug sep oct nov dec);
my %monthindex; @monthindex{@months} = 0 .. $#months;
my @sorted = map $_->[0],
    sort { $a->[1] <=> $b->[1] || $a->[0] cmp $b->[0] }
    map [ $_, $monthindex{substr lc, 0, 3}],
      @files;
[download]