Re: Strict, my and warnings

Yes, the -w switch is acceptable - there was in fact no warnings pragma before Perl 5.6, so it's a fairly recent thing. I still prefer -w for the time being as I never need to switch off warnings anywhere, anyway. (The warnings pragma allows for a more finegrained control if you do: you don't have to switch warnings off entirely anymore, you can selectively disable only specific ones.)

The script is fine, "clean" wise, but could be written quite a lot more succintly. The only technical mistake is writing "$WH" etc where $WH (without the quotes) would do. If you're only using a single variable, you almost never want to put it in quotes. (There are a rare few cases, but you'll know those when you see them.)

One thing I strongly urge you to, though, is to properly indent your code. It is barely acceptable in that short script, but would make a more complex one completely unreadable.

Another note is that you're outputting a CGI header in your printGIF routine: if you go to the trouble of writing a function, then make it do exactly one thing. In this case, generate a GIF file. Nothing else. The header, in this case, is the main program's job. That way, you get functions you can reuse in other scripts later. For the same reason I would have the function return the GIF file, rather than printing it to STDOUT directly.

Which brings up another point you might want to know about: the $|++; I dumped in there. See Suffering from Buffering about it.

Here's how I'd write that:

#!/usr/bin/perl -w
# this script outputs a gif 
# set color, width, and height
use strict;

$|++;

binmode STDOUT;

print "Content-Type: image/gif\n\n";
print gif_file "FF0000", 0x33, 0x10;

######################################
sub gif_file{
    my ($hexrgb, $wid, $hgh) = @_;

    my %c;
    @c{qw(r g b)} = map hex, unpack "A2"x3, $hexrgb;

    return pack "C*", (
        0x47, 0x49, 0x46, 0x38, 0x37,  0x61,  $wid,  0x00,
        $hgh, 0x00, 0xA1, 0x01, 0x00, $c{r}, $c{g}, $c{b},
        0xFF, 0xFF, 0xFF, 0x00, 0x00,  0x00,  0x00,  0x00,
        0x00, 0x21, 0xF9, 0x04, 0x05,  0x00,  0x00,  0x01,
        0x00, 0x2C, 0x00, 0x00, 0x00,  0x00,  $wid,  0x00,
        $hgh, 0x00, 0x40, 0x02, $hgh,  0x84,  0x8F,  0xA9,
        0xCB, 0xED, 0x0F, 0xA3, 0x9C,  0xB4,  0xDA,  0x8B,
        0xB3, 0xDE, 0x9C, 0x17, 0x00,  0x3B,
    );
}
[download]

I would normally have used $width and $height instead of the shorter forms, but wanted to keep the hexdump aligned and somewhat compact.

Makeshifts last the longest.

Comment on Re: Strict, my and warnings Download Code

Replies are listed 'Best First'.
Re: Re: Strict, my and warnings by demerphq (Chancellor) on Oct 16, 2002 at 19:23 UTC
I never need to switch off warnings anywhere, Interesting. There a bunch of modules that I routinely use that produce warnings under -w. In fact I spent a day trying to figure out what I was doing wrong, only to realize that my colleague had slipped a -w into the script and that nothing was wrong. (Win32::Eventlog is the latter mentioned module) Personally I think that the late introduction the warnings modules and its consequent slow takeup and usage was one of the few serious language errors that was made in the earlier versions of perl. (Strong words I know, but im entitled to an opinion :-) I suspect that perl6 will have a quite powerful warning and strictures structure from the get-go as a lesson learned from this. --- demerphq my friends call me, usually because I'm late....	[reply]
Re^3: Strict, my and warnings by Aristotle (Chancellor) on Oct 17, 2002 at 00:30 UTC
Slap the module author(s) on the wrist. Lexically disabling warnings will work under `-w` and of course you can localize `$^W` as we used to do. So I don't see any excuse not to take the proper action to disable them as needed if you're intentionally doing something that may raise warnings. My take on this is fairly rigid. There are times that call for not complying with warnings or strict, but you should at least have the decency not to force that choice unto whoever is using your code as well. File a bug report or complain to the author by email. Makeshifts last the longest.	[reply]
Re: Re: Strict, my and warnings by true (Pilgrim) on Oct 16, 2002 at 11:55 UTC
Didn't see anything in the link about $\|++ Do you mean $\|=1	[reply]
Re^3: Strict, my and warnings by Aristotle (Chancellor) on Oct 16, 2002 at 12:04 UTC
Yes, `$\|++` and `$\| = 1` are equivalent. (Because Perl only ever lets `$\|` be 0 or 1. So if you increment it, it can only become 1. perldoc perlvar should have info on this.) Makeshifts last the longest.	[reply]