Bloodelf has asked for the wisdom of the Perl Monks concerning the following question:

I use the following snippet of code, to add a comment box into a cell on an Excel spreadsheet. 
$commentcell->AddComment;
commentbox=$commentcell->Comment;
$commentbox->Text({Text => $details});

[download]
I now need to resize the comment box. I've played around with SetRange and ScaleWidth, but can't quite get it right - any ideas???
Many thanks.

Replies are listed 'Best First'.
Re: Win32::OLE Excel Comment Box
by jmcnamara (Monsignor) on Nov 06, 2002 at 11:43 UTC

    Here is a short example: 
        #!/usr/bin/perl -w

    use strict;
    use Cwd;
    use Win32::OLE;

    my $application = Win32::OLE->new("Excel.Application");
    my $workbook    = $application->Workbooks->Add;
    my $worksheet   = $workbook->Worksheets(1);


    my $cell1 = $worksheet->Range("A7:A7");
       $cell1->AddComment();

    my $comment1 = $cell1->Comment();
       $comment1->Text({Text => "Unscaled"});


    my $cell2 = $worksheet->Range("A9:A9");
       $cell2->AddComment();

    my $comment2 = $cell2->Comment();
       $comment2->Text({Text => "Scaled"});
       $comment2->Shape->ScaleWidth(2, 0, 0);


    my $dir = cwd();

    $workbook->SaveAs($dir . '/comments.xls');
    $workbook->Close;

    [download]

    You can modify this to use other "Shape" methods as required.

    --
    John.

[reply]
[d/l]
      Many thanks.
[reply]

Back to Seekers of Perl Wisdom