#!/usr/bin/perl -wl

    use strict;

    my @db = qw(aaa bbb ccc ddd eee fff);
    my @in = qw(aaa fff);
    my %h;

    # Initialise the hash using a slice
    @h{@in} = undef;

    print "@db";

    @db = grep {not exists $h{$_}} @db;

    print "@db";

    __END__

    Prints:

    aaa bbb ccc ddd eee fff
    bbb ccc ddd eee
[download]

--
John.

Use a hash slice to build a lookup table:

use strict;
use warnings;

my @db = (1, 3, 5, 7, 9, 11);
my @in = (1, 2, 5, 8, 9, 10, 13);
my %lookup;
my @result;

@lookup{@in} = ();
foreach my $elem (@db) {
  push(@result, $elem) unless exists $lookup{$elem};
}

print "@result\n"; # should print 3 7 11.
[download]

Of course, this doesn't actually remove the elements from @db. It creates a new array, @result, that holds only those elements of @db that were not also on @in. If your array is very, very large and you wish to avoid making a copy, this could be a problem.

From your example code (ignoring the [assumed typo] syntax error), it seems like you don't necessarily want to remove the array element but, rather, want to delete any occurrences of $in in each element of @db. If that's the case, just use a nested loop...

foreach my $db (@db) {
  foreach my $in (@in) {
    $db =~ s/$in//g;
  }
}
[download]

But if you actually want to remove any elements of @db that exactly match one of the elements of @in, then use one of the previous suggestions. :)

bbfu
Black flowers blossum
Fearless on my breath

Now is my chance to try them out. Cheers!