use strict;
my $input="19600326";
substr (((substr ($input,4,0) = '-'),$input),7,0)='-';
print "$input\n";
__END__
1960-03-26
[download]

CU
Robartes-

my @ar = qw(foo 19600326 bar);
$ar[1] =~ s{^(\d{4})(\d{2})(\d{2})\z}($1-$2-$3);
print $ar[1], $/;

__output__

1960-03-26
[download]

_________
broquaint

TIMTOWTDI:

my $date = '19600326';

my $first  = join '-', unpack 'a4 a2 a2', $date;
my $second = sprintf '%s-%s-%s', unpack 'a4 a2 a2', $date;
[download]

After Compline,
Zaxo

my $data = '19600326';

print join('-', unpack('A4A2A2', $data));
[download]

my $data = '19600326';

printf ('%s-%s-%s', unpack('A4A2A2', $data));
[download]

Update: Ack! Zaxo beat me to it by a couple of minutes. :-)

    my $date    = '19600326';

    my $newdate = join '-', $date =~ /(....)(..)(..)/;
[download]

--
John.

Is it always in this (YYYYMMDD) format..? This will work..

#! perl

use strict;

my $s = "19600623";

my $yy = substr($s, 0, 4);
my $mm = substr($s, 4, 2);
my $dd = substr($s, 6, 2);

print "$yy-$mm-$dd\n";
[download]

Prints out 1960-06-23

Update: A little slow when I checked again..;)

Whene there are so many WTDI, a Benchmark may be appropriate to chose:

my $olddate = '20020131';

MyBenchmark::benchmark(
        $ARGV[0],[
        ['regexp \d{}' => sub {
                my $new;
                $olddate =~ m/^(\d{4})(\d{2})(\d{2})$/ and
                $new = "$1-$2-$3";
                $new
        }],
        ['regexp ..' => sub {
                my $new;
                my @p = $olddate =~ /^(....)(..)(..)$/;
                $new = join '-',@p;
                $new
        }],
        ['s/// \d{}' => sub {
                my $new = $olddate;
                $new =~ s/^(\d{4})(\d{2})(\d{2})$/$1-$2-$3/;
                $new
        }],
        ['substr'  => sub {
                my $new = $olddate;
                substr (((substr ($new,4,0) = '-'),$new),7,0)='-';
                $new
        }],
        ['join unpack' => sub {
                my $new;
                $new = join '-', unpack 'a4 a2 a2', $olddate;
                $new
        }],
        ['sprintf unpack' => sub {
                my $new;
                $new = sprintf '%s-%s-%s', unpack 'a4 a2 a2', $olddate
+;
                $new
        }],
        ], '2002-01-31' #expected output
);
[download]

Note that MyBenchmark::benchmark is just a function i've written that executes all subs beforehand and compares their results with an expected value. The benchmark itself is done via Benchmark::cmpthese.

join unpack is fastest for me, sprintf unpack is next.

Hi,
I tried to optimize the substr solution a little.
Now it outperforms join unpack about 70%!


['substr faster'  => sub {
   my $new = $olddate;
   substr($new, 0, 4, substr($new,0,4)."-");
   substr($new, 0, 7, substr($new,0,7)."-");
   $new
}],
[download]

Greetings
MP

$a = "19600326";
$a =~ s/(\d{4})(\d{2})(\d{2})/$1-$2-$3/;
print "$a\n";
[download]

rdfield

In the spirit of TIMTOWTDOI...

#!/usr/bin/perl
use strict;
use warnings;

my @input=<DATA>;

for my $input (@input) {
  chomp $input;
  my @characters=split//,$input;
  my $output;
  for my $i (0..$#characters) {
    $output .= "-" if ($i == 4 || $i == 6);
    $output .= $characters[$i];
  }
  print $output,$/;
}

__END__
19600326
19720309
19730303
19921122
19931120
19960629
[download]

#!/usr/local/bin/perl -w
use strict;
my $olddate = "20020911";
my $newdate;

map { /([\d]{4})([\d]{2})([\d]{2})/; $newdate= "$1-$2-$3"; } $olddate;

print $newdate."\n";
[download]

map in void context is bad. In your case, it's really useless...

$olddate =~ /(\d{4})(\d{2})(\d{2})/ and
$newdate = "$1-$2-$3";
[download]

--
http://fruiture.de