And in the spirit of TIMTOWTDI:

my $string = "The quick brown fox jumps over the lazy dog.";
my $count = 0;
$count++ while $string =~ /(the)/gi;
[download]

This is useful if, for example, you want to operate on a particular occurence of a match. For example, if you wanted to grab the second occurence of particular item in every line of log file:

while (<IN_FILE>) {
  my $count = 0;
  MATCH: while (/(\Q$some_string\E)/gi) {
    $count++;
    if ( 2 == $count ) {
      # do something
      last MATCH;
    }
  }
}
[download]

Cheers,
Ovid

New address of my CGI Course.
Silence is Evil (feel free to copy and distribute widely - note copyright text)

There's no point in putting parenthesis around the search pattern, is there? I find it remarkably that 3 out of the 5 followups so far put parenthesis around the search pattern, without using $1.

Abigail

You're right. I was just a-cuttin' and a-pastin' and not paying attention. That's a very bad habit of mine. Thanks for the reminder.

Cheers,
Ovid

New address of my CGI Course.
Silence is Evil (feel free to copy and distribute widely - note copyright text)

Your problem is that tr/// is not a regex operator in the true sense. It always operates character by character.

What you have actually asked perl to do with the line

my $count = ($str =~ tr/(the)//);

• Inspect the variable $str,
• Look for any of the characters '(', 't', 'h', 'e',')', and if it finds them, as the replacement list is empty, just count them.
• return a count of the number of characters found in $str that were in the searchlist.

One way to count the occurances of a given word in a string would be to use the m// operator with the /g option and force a list context as in

my $str = "The quick brown fox jumps over the lazy dog";
my $count =  () = $str =~ m/(the)/ig;
print $count;
[download]

will print 2.

However, that is still not quite right as using it on the string 'There are three theatres in the town' and it will print 3! This is because the regex /(the)/ will also match the first 3 chars of 'There' and 'theatre'. To ensure that you will only match whole words you can bracket the work with \b - 'word boundary zero-width assertions' like this

my $str = "There are three theatres in the town";
my $count =  () = $str =~ m/(\bthe\b)/ig;
print $count;
[download]

which will correctly print 1.

my $str = "The quick brown fox jumps over the lazy dog";
my $count =  () = $str =~ m/(\bthe\b)/ig;
print $count;
[download]

which will correctly print 2. (Note: the /i modifier to make the match case independant.)

my $str = "The quick brown fox jumped over the lazy dog";
my @the = ( $str =~ /\bthe\b/gi );
print scalar @the, $/;
[download]

update: It would be clearer (I hope) to say that "tr///" treats every character in the left-hand side as a member of a character class; it cannot treat any sequence of characters as a contiguous string to be matched; only the "m//" operator (and the "s///" operator) can do that. Look carefully at the "perlop" man page for more complete descriptions of these three operators.

use warnings;
use strict;

my $str = "The quick brown fox jumps over the lazy dog";
my $count = ($str =~ s/(the)/$1/gi);
print "$count\n";
[download]

1. h in The
2. e in The
3. e in over
(4,5,6) t,h,e in the

which are characters occuring in the Replacement list.

-enlil

Probably tr isn't what you want here, and there's no need to capture the word, so no parentheses. A simple solution is:

my @count = $str =~ /\bthe\b/gi;
print scalar @count, "\n";
[download]

The idea is that g searches globally while i makes the search case-insensitive. Assigning the results to an array means that the @count is populated with all of the successful matches. Placing the array in scalar context will return the number of matches.