I think you are attacking the problem from a wrong angle. You are walking through your DNA string step by step, instead of jumping through it in increments of three. Also you are using a C-style loop, which is very error prone, in your case for example the first element of @dna is at $dna[0]. I'd rewrite your code in the following way, jumping forward three slots with every round :

use strict;
my $i = 2;

my @dna = split //, 'CTCCGGATCTAT';
my $counter = 0;
my $total = 0;

while ($i < @dna)     {
   if ($dna[$i] eq 'C')    {
          $counter++;
    }
   elsif ($dna[$i] eq 'G')   {
          $counter++;
   }
   $total++;
   $i += 3;
 }
print "Found $counter G/C of $total elements at a 3-position\n";
[download]

perl -MHTTP::Daemon -MHTTP::Response -MLWP::Simple -e ' ;    # The  
$d = new HTTP::Daemon and fork and getprint $d->url and exit;#spider
($c = $d->accept())->get_request(); $c->send_response( new   #in the
HTTP::Response(200,$_,$_,qq(Just another Perl hacker\n))); ' #  web
[download]

$i $i+3
1 4
2 5
3 6

I think what you are looking for is something more along these lines (as a for loop):

for ( my $i = 2; $i < @dna; $i = $i+3 )
{
  print "$dna[$i] at position $i\n";
  if ( $dna[$i]  eq 'C' or $dna[$i] eq 'G')
  {
   $counter++;
  }
}
[download]

-enlil

Here is my solution:

use strict;
use warnings;
my $string = "CTCCGGATCTAT";
my $sets = length($string)/3;                # we want to know how man
+y sets of 3 there are
my $unpacker = 'A3' x $sets;                 # create our unpack templ
+ate
my @dna = unpack($unpacker, $string);        # create the array of set
+s
my $counter = 0;                             # initialize the counter

for my $set (@dna) {                         # for each $set in @dna d
+o...
  my $check = substr($set, 2, 1);            # get the 3rd char of the
+ $set
  ++$counter if ($check =~ /[GC]/i);         # increment the counter, 
+ignore case
}
print "$counter/$sets was either C or G.\n"; # print results
[download]

Why so complicated?

use strict;
use warnings;

my $string = "CTCCGGATCTAT";
my $counter = 0;

$counter++ while $string =~ /..[GC]/gi;

print "Found $counter occurences$/";
[download]

Oops, duh. I even tested. %-/

use strict;
use warnings;

my $string = "CTCCGGATCTAT";
my %flag = (C => 1, G => 1, A => 0, T => 0);

my $counter = 0;
$counter += $flag{$1} while $string =~ /..(.)/g;

print "Found $counter occurences$/";
[download]

Makeshifts last the longest.

Ugh, had to read BrowserUk's approach twice to see what was going on. Mine isn't as simple as it started out either - raaa, so obvious in hindsight: my $count = grep /[GC]/, $dna =~ /..(.)/g; There. It slices, it dices, it counts DNA bases. (Or is that RNA? Anyway.)

Makeshifts last the longest.

Why so complicated? ;)

my $count=0;
$count += substr($dna, $_, 1) =~ /[CG]/ for map 3 * $_, 1 .. length($d
+na)/3;
print $count;
[download]

---

Examine what is said, not who speaks.

Why so complicated?

1. TIMTOWTDI
2. The comments shed light on how it works
3. It worked the first time. q-:
4. Why not?

Try incrementing by three rather than by one and then looking ahead three. At present, you're iterating over each element in the array and then checking to see the value of your index plus 3. So you're seeing 4, then 5, 6, 7, since you start counting at 1. Try a loop construct like:

for ($i = 2; $i < @dna; $i += 3) # assuming your start index is 0
[download]

Dingus