my @arr1 = qw(2 4 5);
my @arr2 = ('1,nfs', '2,afp', '3,cifs', '4,dns', '5,backup');

my %arr1_as_hash;
$arr1_as_hash{$_}++ for @arr1;
my @arr3 = map {
  my ($key, $val) = split /,/;
  $arr1_as_hash{$key} ? $val : ();
} @arr2;
[download]

-- Randal L. Schwartz, Perl hacker
Be sure to read my standard disclaimer if this is a reply.

For variety, here's a solution that uses a kind of Schwartzian Transform (but grepping instead of sorting).

  my %arr1_as_hash;
  @arr1_as_hash{@arr1} = ();
  my @arr3 =
    map { $_->[1] }
    grep { exists $arr1_as_hash{$_->[0]} }
    map { [ split /,/ ] }
    @arr2;
[download]

jdporter
The 6th Rule of Perl Club is -- There is no Rule #6.

use Data::Dumper;

my @arr1 = qw(2 4 5);
my @arr2 = ('1,nfs', '2,afp', '3,cifs', '4,dns', '5,backup');
my @arr3 = map { (split /,/)[-1] } grep { /^[@arr1],/x } @arr2;

print Dumper(\@arr3);

__output__

$VAR1 = [
          'afp',
          'dns',
          'backup'
        ];
[download]

_________
broquaint

what is the shortest way?

I don't know about shortest. Don't feel like playing golf today, sorry :)

# untested

my %foo = map { split /,/, $_, 2 } @arr2;
my @arr3 = map { exists $foo{$_} ? $foo{$_} : () } @arr1;
[download]

- Yes, I reinvent wheels.
- Spam: Visit eurotraQ.

I tested this one. It works and wins my vote for shortest and cleanest.

But you're wrong. :-)

    my @arr3 = @foo{@arr1};
[download]

And if you don't mind very short but somewhat dirty, you can do this:

    my %foo = map{/,/;$`,$'} @arr2;
[download]

jdporter
The 6th Rule of Perl Club is -- There is no Rule #6.

my @arr1 = (1 3 4); # remember arrays are zero based
my @arr2 = qw( nfs afp cifs dns backup);
my @arr3 = @arr2[@arr1]; # slice notation
[download]