The following code should do what you want, provided that the tags always start at the same letter (from the beginning or end - see the DATA section for what I mean by that).

Instead of just creating the simple pairs you might be able to shift the player names characterwise against each other. Then you might get to a solution that doesn't contain the above stated restriction.

use strict;
use warnings;
use List::Util qw/reduce/;

sub _extract {
    my @names = @_;
    my @pairs;

# create all xor'd pairs
    for(my $i=0; $i<@names; $i++) {
        for (my $j=$i+1; $j<@names; $j++) {
            push @pairs, $names[$i] ^ $names[$j];
        }
    }

    no warnings 'once';
    my $or = reduce { $a | $b } @pairs;

    if ( $or =~ /\0+/ ) {
        my $index = $-[0];
        my $length = $+[0] - $-[0];
        return substr $names[0], $index, $length;
    } else { # match not successful, so return undef
        return;
    }
}

sub extract_tag {
    my @names = @_;
    my $tag;

    $tag = _extract(@names);

# try matching with reversed @names
# this finds common substrs at the end
    $tag = reverse _extract(map {scalar reverse $_} @names)
        unless defined $tag;

    return $tag;
}


my @names;
local $, = ':';
local $\ = "\n";

while (<DATA>) {
    chomp;
    print(extract_tag(@names)), @names = (), next unless /\S/;
    push @names, $_;
}
print extract_tag(@names);

__DATA__
jP|Azrael
jP|Blade
jP|Henry

Jeff.ocr
pr!me.ocr
Lokren.ocr

woRUTtan
hiRUTfango
biRUTff

salTAGo
blasTAGi
RipTAGu
[download]

-- Hofmator

Thank you very much!
This is exactly what i was searching for :)
I think this will catch at least 95% of the common tags.

But i am still astonished that there is no module for this problem.

The examples you give use a non-word character as a delimeter. Is that always the case? If so,

my @name_parts = split /(\W)/, $name;
my $clantag = exists $clanhash{$nameparts[0]}
              ? $nameparts[0] . $nameparts[1]
              : $nameparts[1] . $nameparts[2];
[download]

After Compline,
Zaxo

Sadly it isn't that easy.
You'd be suprised how creative people can be if it gets to inventing a clantag ;)
But nevertheless: Thank you

Careful; what you want to do isn't possible to do 100% huristicly. Consider a clan which has two members, SC|Adam, and SC|Alex. The clantag isn't SC|A, even though that's teh longest common substring, it's SC|, and they both happen to have names beginning with an A.

Also, consider SCSuperBot, SCMegaBot, and SCWackoBot. The clantag is SC, not Bot, or both, but the longest common substring is Bot.

Anyway, don't let this discourage you too much, I just wanted to note it.

MJD says you can't just make shit up and expect the computer to know what you mean, retardo! ** The Third rule of perl club is a statement of fact: pod is sexy.

The problem is that i have no control over the interface. The data is generated by players on online gameservers. The names are chosen by the clans and all i can do is reading them from logfiles or via udp.