in reply to Complicated pattern match

In general, it seems like you want to take the sequence of charaters in $A, make sure $B contains those characters, in that sequence, but with other stuff inbetween them. Then you want a list of the other stuff.

This should do it: 

#!/usr/bin/perl
use warnings;
use strict;

my $A = 'ATGGAGTCGACGAATTTGAAGAAT';
my $B = 'xxxxxxATGGAGyxxxTCGAzxxxxCGAATTTGAAxxwGAAT';

my @A = split //, $A;
my $Are = '^(.*)' . join('(.*)', @A) . '(.*)$';
my @introns = ($B =~ m/$Are/);
if (!@introns) {
 die "There was no possible way to match the input.";
}
foreach (0..$#introns) {
 print "$_: $introns[$_] $A[$_]\n";
}

[download]
That should give you @introns as a list of everything that /didn't/ match. There will be zero-length strings for each position in which there was no junk, and otherwise the junk. Look at the output, and you'll see what I mean. Also, if there is more then one way of matching $B against $A, this will take each section of @introns to be as long as possible. If you'd prefer it as short as possible, that's easily possible. In either case, it will try it's hardest to get them to match. It will allow both leading and trailing junk, though your example only has trailing junk. These are left as exercises for the reader.

Update: Major revisions to code, changed caveats, tested.

Warning: Unless otherwise stated, code is untested. Do not use without understanding. Code is posted in the hopes it is useful, but without warranty. All copyrights are relinquished into the public domain unless otherwise stated. I am not an angel. I am capable of error, and err on a fairly regular basis. If I made a mistake, please let me know (such as by replying to this node).

Replies are listed 'Best First'.
Re^2: Complicated pattern match
by Aristotle (Chancellor) on Jan 19, 2003 at 12:21 UTC
    You can simplify this: 
    my $Are = '^(.*)' . join('(.*)', @A) . '(.*)$';

    [download]
    Like so: 
    my $Are = join '(.*)', '^', @A, '$';

    [download]

    I'd also use a nongreedy .*? there instead.

    You provided a code base I liked quite a bit and couldn't stop tinkering with though - that temporary @A was annoying. :) Eventually it occured to me I could just capture the matches from $A as well: 

    my $Are = join '(.*?)', '^', (map "($_)", $A =~ /(.)/sg), '$';

    [download]
    Now it all goes in a single array where every odd element is guaranteed to be one character long, while every even element may have any length incl zero. With that in mind, I wrote a cleanup loop and eventually arrived at this: 
    #!/usr/bin/perl -w
use strict;

my $A = 'ATGGAGTCGACGAATTTGAAGAAT';
my $B = 'xxxxxxATGGAGyxxxTCGAzxxxxCGAATTTGAAxxwGAAT';

my $Are = join '(.*?)', '^', (map "($_)", $A =~ /(.)/sg), '$';

(my @introns = $B =~ m/$Are/)
    or die "There was no possible way to match the input.";

my @seq;
while(@introns) {
    my $match = shift @introns;
    if(@seq and not $match) {
        $seq[-1] .= shift @introns || '';
        next;
    }
    push @seq, $match;
}

print "$A\n@seq\n";

__END__
ATGGAGTCGACGAATTTGAAGAAT
xxxxxx ATGGAG yxxx TCGA zxxxx CGAATTTGAA xxw GAAT

    [download]

    Update: hrm.. it doesn't work so well anymore once you substitute "real" sequences for the dummy characters in $B..

    ATGGAGTCGACGAATTTGAAGAAT
    ATGGAG A T GGAGT CGA T CGAA G T CACCGAA TT T GAA TTT GAAT

    I suspect nearly the same is true for theorbtwo's code due to the nature of pattern matching.

    Makeshifts last the longest.

[reply]
[d/l]
[select]

In Section Seekers of Perl Wisdom