Given an array what is the best way to return it as a list?

_________
broquaint

--Reposting my answer from the duplicated node--

I think you're confused by the distinction between arrays and lists. Lists are a bunch of values, while arrays are variables that hold values. See perlfaq4.

Outside your subroutine, the distinction doesn't matter. It will all look like arrays:

sub return_array {
   my @a = (0, 1, 2, 3);
   return @a;
}
sub return_list {
   return (0, 1, 2, 3);
}

my @array1 = return_array();
my @array2 = return_list();
[download]

Outside your subroutine, the distinction doesn't matter.

It does, depending on context. See Context aware functions - best practices? for an example of this.

It will all look like arrays

(Assuming list context.) Make that "lists" instead. A bunch of values are returned, and as you say yourself, that's a list.

If you really want to return a list but the whole list is stored in an array you can do   return @stuff[0..$#stuff];

ihb

My thought on this is that, if the dictates of your application lend or require you to return a list, rather than a ref, try and return the list without building an array first, if it's sensible to do so.

As a example, rather than

sub get_3d_xyz { 
    $self = shift;
    my @xyz = ( $self->get_x()
              , $self->get_y()
              , $self->get_z() );

    return @xyz;
}
[download]

save allocating and building the intermediate lexical array and do

sub get_3d_xyz { 
    $self = shift;
    return ( $self->get_x(), $self->get_y(), $self->get_z() );
}
[download]

Or even,

use constant SELF => 0;
sub get_3d_xyz { 
    ( $_[SELF]->get_x()
    , $_[SELF]->get_y()
    , $_[SELF]->get_z() ); 
}
[download]

Each of those steps shaves a few micro/milliseconds of the operation. Not a lot as and of itself, but at the heart of a 3d-graphic class, significant enough.

Updated: Corrected a couple of typos. Thanks ihb.

!/usr/bin/perl
use strict;
use warnings;

sub list { return ( "a", "b", "c") }

sub array {
   my @ret = ( "a", "b", "c");
   return @ret;
}

sub ar_as_list{
   my @ret = ( "a", "b", "c");
   return $ret[-1] unless wantarray;
   return @ret;
}

my $a = list();
my $b = array();
my $c = ar_as_list();

print "list >$a<\narray >$b<\nar_as_list >$c<\n";

__DATA__
list >c<
array >3<
ar_as_list >c<
[download]

Your model is perhaps flawed. At no time does Perl "return" an "array".

A more accurate model is that Perl calls a subroutine with a flag that says "I want a scalar" or "I want a list". When the last expression of the subroutine is evaluated (such as for a return operator), that subroutine gets scalar or list eval context applied to it, as appropriate.

So, a subroutine returns a list or scalar. Always. It never returns an array. If you write return @a, it will return the length of array @a in a scalar context, or a list copied from the contents of @a in a list context. At no time has it "returned" the "array" @a.

Clear now?

-- Randal L. Schwartz, Perl hacker
Be sure to read my standard disclaimer if this is a reply.

Hi ,



      sub array{

          my @ret = ( "a", "b", "c", "d");
          return \@ret;

     }

     my $b = &array();

     my @B = @$b;
[download]

     sub list {

           return(1,2);
 
     }
[download]

     sub arrays {
    
          @A = (1,2);
          return (\@A);

     }
[download]