use version;

my $v1 = version->new("1.4.10");
my $v2 = version->new("1.4.6");

print $v1->stringify," > ",$v2->stringify," = ",
     ($v1 > $v2 ? "true" : "false"), $/;

__output__

1.4.10 > 1.4.6 = true
[download]

_________
broquaint

my $old_version = '1.4.10';
my $new_version = '1.6.0';

my @old_version = split /\./, $old_version;
my @new_version = split /\./, $new_version;
my $cmp = 0;

$cmp ||= ($old_version[$_] <=> $new_version[$_]) for (0 .. $#old_versi
+on);

if ($cmp == 0) {
    print "$old_version == $new_version\n";
} elsif ($cmp == 1) {
    print "$old_version > $new_version\n";
} else {
    print "$old_version < $new_version\n";
}
[download]

blokhead

use Sort::Versions;

@l = sort { versioncmp($a, $b) } qw( 1.2 1.2.0 1.2a.0 1.2.a 1.a 02.a )
+;
[download]

-- Hofmator

I'd agree with broquaint above about using the module, but if that's not do-able for some reason a way around this is to take the string, split it into it's components, zero-pad these to a long length, rejoin them, and compare on the end results. Note that this will only work if they have the same number of components, 1.1.5 > 2.0.

The code below incorporates this into a sort routine. If this was to be used for big arrays I'd recommend doing a Schwartzian Transformation using it to avoid the overhead, but for small arrays this shouldn't be too much of a problem.

#!/usr/bin/perl
use strict;
use warnings;

my @test_data = qw(2.0.0 1.2.0 1.2.10 1.1.15 1.2.1 1.2.0);
print "$_\n" foreach sort {cmp_versions($a,$b)} @test_data;

sub cmp_versions {
  my ($a, $b) = @_;
  $a = join '', map { sprintf '%08d', $_ } split /\./, $a;
  $b = join '', map { sprintf '%08d', $_ } split /\./, $b;
  return $a cmp $b;
}
[download]

Concatenating 'v' to the front of each version string and evaling using eq, gt,lt or cmp seems to work okay. I'm sure I saw 'vMMM.nnn.rr' described somewhere in the docs, but I couldn't find it anywhere just now?

#! perl -slw
use strict;

sub map2 (&@) {
    use Carp;
    my $code = shift;
    croak 'Odd number of values in list' if @_ & 1;
    map { local ($a, $b) = (shift,shift); $code->() } 1 .. (@_>>1);
}

sub cmpVer{ eval{'v'.$_[0] cmp 'v'.$_[1];} } # << This is the salient 
+bit

my @a = qw[
    1.1.1    1.1.1
    1.1.1    1.1.2
    1.1.2    1.1.1
    1.1.10    1.2.0
    0.111.0    9.0.0
    9.0.0    0.111.0
    1.4.999    1.5.0
];

map2{
    printf "%10s %2.2s %s\n", $a, (qw/== > </)[cmpVer($a, $b)], $b;
} @a;
__END__
C:\test>228707
     1.1.1 == 1.1.1
     1.1.1  < 1.1.2
     1.1.2  > 1.1.1
    1.1.10  < 1.2.0
   0.111.0  < 9.0.0
     9.0.0  > 0.111.0
   1.4.999  < 1.5.0

C:\test>
[download]

If anyone can tell me why I can't supply a qw// list directly to my map2 sub

map2{ print $a, $b; } qw[a b c d];
[download]

without getting syntax errors, I'd like to hear the explanation.