This appears to do what you want.

#!/usr/bin/perl -w

use strict;

#           Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec
my @days = ( 31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31);

my ($d1,$m,$y) = (localtime)[3..5];
$y += 1900;
my $d2;

if ($d1 > 15) {
    $d1 = 1;
    $d2 = 15;
} else {
    if (--$m < 0) {
    $m = 11;
    $y--;
    }
    $d1 = 16;
    $d2 = $days[$m];
}
$m++;
printf "%04d%02d%02d-%04d%02d%02d\n",$y,$m,$d1,$y,$m,$d2;
[download]

---
print map { my ($m)=1<<hex($_)&11?' ':'';
$m.=substr('AHJPacehklnorstu',hex($_),1) }
split //,'2fde0abe76c36c914586c';
[download]

To deal with leap years, you could make the @days array like this:

my @days = (
    [ qw(31 28 31 30 31 30 31 31 30 31 30 31) ], # non-leap
    [ qw(31 29 31 30 31 30 31 31 30 31 30 31) ]  # leap
)
[download]

A function to return 0 when a gives year is not a leap year, and 1 if it is:

sub leap {
    my $y = shift;
    return ($y % 4 == 0 && $y % 100 != 0) || $y % 400 == 0;
}
[download]

and you can use it like

my $leap = leap($y);

...

$days[$leap][$m]
[download]

Arjen

Here's an example using Date::Calc.

This code gets the current day, month and year using Date::Calc::Localtime, rather than the built in localtime().

This code will figure out the number of days in each month.
Leap years are handled correctly.

You could always modify this code so that you can get those numbers yourself outside of the subroutine and have the sub just do the calculations.

#!/usr/bin/perl

use strict;
use warnings;
use Date::Calc qw/Localtime Days_in_Month/;

sub give_dates {

  my ($year, $month, $day) = (Localtime())[0,1,2];
  my $days_in_mon          = Days_in_Month($year, $month);

  my $cutoff = int($days_in_mon / 2);

  my ($start, $end);

  if ( $day <= $cutoff) {
    # First half of month
    $start = $year . sprintf("%02d", $month) . '01';
    $end   = $year . sprintf("%02d", $month) . $cutoff;
  } else {
    # Second half of month
    $start = $year . sprintf("%02d", $month) . $cutoff;
    $end   = $year . sprintf("%02d", $month) . $days_in_mon;
  }
  return ($start, $end);
}

print join " ", give_dates(), "\n";
[download]

Cheers.

BazB

Update: Corrected code. Initial version gave dates in wrong format (YYYYMMMDD not YYYYMMDD).

use warnings;
use strict;

# test routine
for my $y (2001..2002){
  for my $m (1,6,12){
   for my $d (1,15,16,31){
     print "$d\t$m\t$y = ".newrelease($d,$m-1,$y-1900)."\n";
   }
  }
  print "\n";
}

sub newrelease {
  #my ($day,$month,$year) = (localtime)[3,4,5];
  my ($day,$month,$year) = @_; # testing
  # make normal
  $year+=1900;
  $month+=1;

  # return values
  my ($start_date,$end_date);

  # logic
  if ($day > 15){
    # easy one same month
    $month = sprintf "%02d",$month;
    $start_date = $year.$month."01";
    $end_date   = $year.$month."15";
  } else {
    # day is 15 or less use previous month
    # if now jan then prev month is dec last year
    if ($month == 1){
      --$year;
      $month=12;
    } else {
      $month = sprintf "%02d",$month-1;
    }
    $start_date = $year.$month."16";
    $end_date   = $year.$month."31";
  }
  return "$start_date to $end_date";
}
[download]

Here is what I have written so far, I tried to do it using Date::Time, but I'm not familliar with the module.

Not being familiar with a module is not really a good reason to not use it. Experiment with it and maybe someday a problem comes by which you can solve with that module because you knew it existed and played around with it.

Arjen

use strict;
my ($day, $month, $year) = (localtime) [3, 4, 5];
$year += ($month += ($day = $day > 15 ? 0 : 15) ? 11 : 0) == 11 ? 1899
+ : 1900;
my ($start_day, $end_day) = map {sprintf("%4.4d%2.2d%2.2d", $year, $mo
+nth % 12 + 1, $_)} ($day, $day ? 31 : 15);
print "New Releases from $start_day to $end_day \n"
[download]

Of course, Perl's shortcuts sometimes do make code hard to read, and I may have crossed the line somewhat into obfuscation territory to make my point. But used carefully, they support a brevity that can actually foster comprehension by stripping a script of redundancy.

As with any code you get from the Monks, "try it before you buy it". I may have overlooked something. :-)

%num = (
   Jan => '01', Feb => '02', Mar => '03', Apr => '04',
   May => '05', Jun => '06', Jul => '07', Aug => '08',
   Sep => '09', Oct => '10', Nov => '11', Dec => '12'
);
  
($day,$mth,$year) = (localtime)[3,4,5];

if ($mth =~ /Jan/) {
# If its jan we need last year to this year
   $s_year = $year - 1;
   $e_year = $year;

} else {
   $s_year = $year;
   $e_year = $year;
}

if ($day <= 14) {
# Get last half of last month
   $s_day = '16';
   $e_day = '01';   

   $s_month = $num{$last{$mth}};
   $e_mth   = $num{$mth};

} else {
# Get the beginning of this month
   $s_day = '01';
   $e_day = '15';

   $s_month = $num{$mth};
   $e_month = $num{$mth};
}

$query = 'SELECT * from newreleases ';
$query = 'WHERE rel_date >= "$s_year-$s_mth-$s_day" AND rel_date <= "$
+e_year-$e_mth-$s_day";'
[download]