I usually solve this with a subroutine. I'll provide a few - one for regex matching and two for plain 'contains' or 'equals' matching.

The whole idea here is I'm just sticking the operator into a subroutine and calling each value in turn until either the list is exhausted or something matched successfully. I understand this somewhat of the idea behind the junction operators in perl6. Anyhow, check out List::Util for more thoughts along these lines.

 sub qrany { $_ =~ $_[0] && return 1 for @_[1 .. $#_]; return }
 sub cany { index($_[0],$_) != -1 && return 1 for @_[1 .. $#_]; return
+ }
 sub eqany { $_ eq $_[0] && return 1 for @_[1 .. $#_]; return }
 
 # Contains tests
 if (cany( $string, qw[this or_this or_that]) {....

 or
 
 # Equality tests
 if (eqany( $string, qw[this or_this or_that]) {....

 or
 
 # Regex tests
 if (qrany( $string, qr/one regex/,
                     qr/another regex/,
                     qr/yet another regex/ )) { ....
[download]

Updated Added eqany and some comments on the usage of each

UpdatedFixed the words "three and two". Also added the second paragraph

Seeking Green geeks in Minnesota

Your first way will work, except that you need to use the binding operator =~ instead of the equality operator eq:

if ($string =~ m/(this|or_this|or_that)/i)
[download]

For more information on regular expressions perlre is your first stop.

CU
Robartes-

Try this:

if ($string =~ m/^(this|or_this|or_that)$/i) {
 ...
}
[download]

update: Since I'm being downvoted, maybe I wasn't clear enough. I replaced eq with =~ and inserted the ^ (beginning of line) and the $ (end of line) matching operators. This to ensure that you receive an exact match for "this" or "or_this" or "or_that" (otherwise "foothisbar" would have matched).

Thank you, Dempa, and everyone else too :o)

That worked. I have what I guess is called a hash:



@field = (
{name=> "this", size=>2, value=>"none", req=>1},
{name=> "this_one", size=>4, value=>"none2"}
);
[download]


Kind of like that one, but more fields, and obviously different.
I use it for our registration system, however, I also am going to use the same one for a contact us form, but I don't need username, password and so forth, so I when I'm building my form with CGI.pm from that "hash", I am having it skip the fields I don't want in the form, using next if $string eq "name";

I wanted it all to be in the same line though, instead of a bunch of needless code.

It worked.

Thank you!
Richard

The second way, Is much too long, as I'll have several different ones to search, more then 3, less than 10.

To make things more flexible, you can generate your regex on-the-fly using the qr operator. A simple-minded example:

#!/usr/bin/perl -w

use strict;

my $words = join("|", qw(these are words that can be matched));
my $wre = qr/^($words)$/i;

my $w = <STDIN>;

if ($w =~ $wre) {
    print "I know that word\n";
}
[download]

I don't know if it could help your program doing something like this, but it's just an idea.

Arjen

Update: This will only work with strings that do not contain regex metacharacters.

Why not use a list operator in this case? grep comes to mind, but especially first that is in the List::Util module (part of the Perl 5.8 distribution if memory serves).

use List::Util qw( first );
if (defined(first {'abc' eq $_} qw( abc def ghi ))) {
    print "found 'abc'\n";
}
[download]

Hope this helps, -gjb-

Update: Thanks to diotalevi for pointing out issues with my solution. I agree with both: I suggested first for exactly his objection to grep and I modified the original code by adding defined to resolve his objection to find.

Both of these are poor choices. You wouldn't use grep because that's a wasteful way to program. Not only does it not stop after finding a match, it goes to all the trouble to create a copy of the matching elements in memory. The first() function is also poor because that assumes that the data itself evaluates as a 'true' value. That doesn't work when your data is things like "" and 0.

---

Seeking Green geeks in Minnesota

if(grep $string eq $_, qw(this that the_other)) {
    # ...
}
[download]

Makeshifts last the longest.