my %webobj = (       
                'template' => param('template'), 
                'minscale' => param('minscale')
            );
[download]

-- Randal L. Schwartz, Perl hacker
Be sure to read my standard disclaimer if this is a reply.

You get exactly the same result if you do this:

my %webobj = (       
                'template' => ,
                'minscale' => 2
            );
[download]

because there is no param(template), so it's like you said 'template' => nothing, comma, minscale, I guess.

I suppose this is somehow different to doing it with an undefined variable -- that way you'd get undef as the value for 'template'.

I know it's daggy and old-fashioned, but if I'm in a hurry, I just do this:

CGI::ReadParse();
[download]

which puts everything into a hash called %in. That was only included in CGI.pm for backward, perl 4/cgi-lib compatibility, but I like it. It does what you're trying to do here, right?
--


“Every bit of code is either naturally related to the problem at hand, or else it's an accidental side effect of the fact that you happened to solve the problem using a digital computer.”
M-J D

I often do:

use CGI qw(:cgi-lib);
my $form = Vars;
[download]

Gives you a tied hash-reference to all parameters, also allowing you to change the submitted parameters...

thanks, that also works... so my choices are

my %webobj = (       
                'template' => param('template') || '', 
                'minscale' => param('minscale') || ''
            );
[download]

or

my %webobj = (       
                'template' => scalar(param('template')), 
                'minscale' => scalar(param('minscale'))
            );
[download]

From Randal's comment it seems the latter would be the wiser choice.

I am assuming 'minscale' is being assigned as a value to the 'template' key because there is nothing in param('template') and the comma is causing minscale to appear as part of a list.

The quick (and possibly dirty, depending on your POV) is to ensure that your hash has a default value the first-time through.

my %webobj = (
                'template' => param('template')||'',
                'minscale' => param('minscale')||'0'
            );
[download]

A quick test shows this seems to work ok for your example.

thanks for the suggestion. I will take it. However, here's my question. Why does this happen? I mean, I can also do something like

my $template = param('template');
my $minscale = param('minscale');

my %webobj = (
                'template' => $template,
                'minscale' => $minscale
            );
[download]

and then I get acceptable behavior. But, this shouldn't be necessary. In fact, even if I get something strange, why the heck does 'template' => param('template') end up grabbing 'minscale' as its value... that comma after param('template') should tell it to lay off of 'minscale'. Would love to find out why? Many thanks

that comma after param('template') should tell it to lay off of 'minscale'.

It doesn't, though. merlyn has the right of it, as usual. There are no parameters. Calling param() in list context (as happens in the hash assignment) produces an empty list in this case. Since there has to be a value, Perl grabs the next one in a list.

Your snippet is equivalent to:

my %webobj = (
    'template', param( 'template' ), 'minscale', param( 'minscale' ),
);
[download]

Consider what happens if you assign an empty list:

use strict;
use Data::Dumper;

my %hash = ( foo => ,,, bar => 1 => 'baz' );

print Dumper \%hash;
[download]

Your question has been answered in a sufficient manner, but I'd just like to show you something else as well. It's nice if a person picks either the CGI routine or the hand-done routine. What I mean is that you use CGI for outputting headers and even the opening html tag, but then you do the actual page by hand, not using the tools provided by CGI.pm. The one thing I noticed on a once-through through your script is the the row with the submit button is invalid html -> you have a total of 3 columns in this row, while the two preceeding rows have only 2 :) So here's the program, quickly redone to completely use CGI. Untested, but I think I matched all those parentheses and curly braces :)

#!/usr/bin/perl -w
use strict;
use CGI qw/:standard :cgi-lib/;
my $I = Vars;

print header(),
  start_html('Example Page'),
    start_form(),
      strong('Web Object'),
      table(
        Tr(
          td( {align=>'right'}, 'Template' ),
          td( textfield({ name  => 'template' }) )
        ),
        Tr(
          td( {align=>'right'}, 'Minscale' ),
          td( textfield({ name  => 'minscale' }) )
        ),
        Tr(
          td( {colspan=>2}, submit({ value => 'submit' }) )
        )
      ),
    end_form(),
    pre( qq{TEMPLATE "$I->{'template'}"\nMINSCALE "$I->{'minscale'}"} 
+),
  end_html();
[download]

      C:\>shutdown -s
      >> Could not shut down computer:
      >> Microsoft is logged in remotely.
    

my %webojb;
$webobj{template} = param('template');
$webobj{minscale} = param('minscale');
[download]

use strict;
use warnings;
use CGI qw(param);

my $webobj = WebObj->new();
$webobj->template(param('template'));
$webobj->minscale(param('minscale'));

print $webobj->template,$/;
print $webobj->minscale,$/;

package WebObj;

use strict;
use warnings;
use Class::MethodMaker
   new     => 'new',
   get_set => [qw(template minscale)],
;
[download]

./webobj.cgi 'template=foo'
./webobj.cgi 'template=foo&minscale=bar'
./webobj.cgi 'template=foo&minscale=bar&minscale=baz'

jeffa

L-LL-L--L-LL-L--L-LL-L--
-R--R-RR-R--R-RR-R--R-RR
B--B--B--B--B--B--B--B--
H---H---H---H---H---H---
(the triplet paradiddle with high-hat)