skx has asked for the wisdom of the Perl Monks concerning the following question:

 Hello Monks,

 I've got a simple problem with a configuration file parser/settings object.

 I've written a simple module which allows access to configuration values, and I find that I'm not able to differentiate between a value that is unset, and a value that is zero easily.

 Consider the following:

   my $value = getConfigValue( "use_foo" ) || 1;

[download]

 What I want to do is to say read the value, and if it's not defined use '1' as a default. What actually happens is that if the value is set to '0' it gets ignored.

 I see the following as a solution:

   my $value = getConfigValue( "use_foo" );
   if ( !defined( $value ) ) { $value = 1; }

[download]

 but that seems a little messy.

 Short of re-writing the code to be 'getConfigValue( "keyname", "default" )' which would be a pain is there a simple solution?

Steve
---
steve.org.uk

Replies are listed 'Best First'.
Re: undef vs 0
by robartes (Priest) on Feb 06, 2003 at 09:49 UTC
    Use the ?: operator: 
    my $value=defined(getConfigValue("use_foo""))?getConfigValue("use_foo"
+):1;

    [download]
    But your solution does basically the same and is not messy IMO. You could rewrite it as such: 
    my $value = getConfigValue( "use_foo");
$value=1 unless defined $value;

    [download]
    Which looks a bit better (and is more Perlish).

    Please not that code provided is untested.

    CU
    Robartes-

[reply]
[d/l]
[select]
Re: undef vs 0
by PodMaster (Abbot) on Feb 06, 2003 at 10:00 UTC
[reply]
[d/l]
[select]
      The real question is why write such a module when there are tons of them?

       A valid question; basically because this is a perl re-implementation of some C code. The config file parser has to be 100% compatible with the old codes behaviour.

       Also it should be possible for the settings in the configuration file to be overridden by the contents of environmental variables, which no existing code I saw supported.

       (The environmental variable overrides is necessary for my testing scripts/testing system - fully automatic regression testing of the project as a whole, and the modules it is implmented via/with).

      Steve
      ---
      steve.org.uk
[reply]
Re: undef vs 0
by bart (Canon) on Feb 06, 2003 at 11:51 UTC
    That's why perl6 will have the '//' operator. Heck, it could even be that one of the future perl5 versions will have it... Urm... no, perl5.8.0 doesn't have it, yet. You can search through the P5P archives to see any discussions, for example in this message.

    Anyway, a contrived solution could be: 

     my($value) = map { defined() ? $_ : 1 } getConfigValue( "use_foo" );

    [download]
    Perhaps a less vicious example: 
    my $value = do { defined(local $_ = getConfigValue( "use_foo" )) ? $_ 
+: 1 };

    [download]
    You could always write a sub I suppose — perhaps in an external module, if you use it a lot? 
    sub default {
     my $v = shift;
     return defined $v ? $v : shift;
}

my $value = default(getConfigValue( "use_foo" ), 1);

    [download]
[reply]
[d/l]
[select]
Re: undef vs 0
by ehdonhon (Curate) on Feb 06, 2003 at 11:30 UTC

    In perl6, this will be easy:
    my $value = getConfigValue( "use_foo" ) // 1;

    In perl5, I think robartes has the right idea. Just to expand on it though, suppose you only want to call getConfigValue once for each value. You could do this:
    my $value = defined($_ = getConfigValue( "use_foo" )) ? $_ : 1;

[reply]
[d/l]
[select]
Re: undef vs 0
by pfaut (Priest) on Feb 06, 2003 at 15:54 UTC

    If you wrote the module, why not add a second argument to the getConfigValue() function to act as a default value? Then the check for defined is hidden inside the module and your calling code is as simple as my $value = getConfigValue( "use_foo", 1 );.

    ---
print map { my ($m)=1<<hex($_)&11?' ':'';
$m.=substr('AHJPacehklnorstu',hex($_),1) }
split //,'2fde0abe76c36c914586c';

    [download]
[reply]
[d/l]
[select]

       I think that would probably be the most straightfoward solution.

      Steve
      ---
      steve.org.uk
[reply]
Re: undef vs 0
by TheDamian (Vicar) on Feb 07, 2003 at 17:17 UTC
    Yet another solution: 
        my ($value) = grep defined, getConfigValue( "use_foo" ), 1;

    [download]
[reply]
[d/l]
Re: undef vs 0
by PureSignal (Initiate) on Feb 06, 2003 at 18:30 UTC
    this is about the same I guess:

    my $value;
defined ($value = getConfigValue( "use_foo" )) or $value = 1;
[reply]
Re: undef vs 0
by thinc (Novice) on Feb 07, 2003 at 06:48 UTC
    try this: 
    my $value = getConfigValue( "use_foo" ) ||= 1;

    [download]
[reply]
[d/l]

Back to Seekers of Perl Wisdom