my @array = qw(one two);
my @array2 = qw(three four five);
my @array3 = qw (six seven);

format STDOUT =
@<<<<<<<<< @<<<<<<<<< @<<<<<<<<< ~~
shift(@array), shift(@array2), shift(@array3)
.
write STDOUT;
[download]

-- Randal L. Schwartz, Perl hacker
Be sure to read my standard disclaimer if this is a reply.

Off the top of my head, I'd probably do something like this:

while(@array || @array2 || @array3) {
    printf("%-10s %-10s %-10s\n",
        shift(@array) || '',
        shift(@array2) || '',
        shift(@array3) || '',
    );
}
[download]

You could do something similar, and iterate from 0 to the last index of the longest array, and just print the element at that index, but that would require you to figure out how long the longest array was as well, but that might be easier if you need to keep the contents of the array around after printing them.

Thanks jasonk

That's perfect for what I need :)

This one is more generalized and doesn't modify the contents of the arrays. It's clunkier than jasonk's but gives you another option if you need it. It could be cleaned up and made more concise I'm sure ...

use strict;

sub array_cols
{
    my $array_ref;
    my $n = 0;

    foreach $array_ref (@_)
    {
        $n = scalar(@$array_ref) if (scalar(@$array_ref) > $n);
    }

    for (my $i = 0; $i < $n; $i++)
    {
        foreach $array_ref (@_)
        {
            printf "%-12.12s  ", $array_ref->[$i];
        }

        print "\n";
    }
}

my @array1 = (qw/one two/);
my @array2 = (qw/three four five/);
my @array3 = (qw/six seven/);

array_cols(\@array1, \@array2, \@array3);
[download]

A very flexible, non-destructive one-liner.

my @a = qw[one two]; 
my @b = qw[three four five]; 
my @c = qw[six seven];

printf +('%-10s 'x3) .$/
  , $a[$_]||'', $b[$_]||'', $c[$_]||'' 
    for 0 .. ( sort{ $b<=>$a } ~~@a, ~~@b,~~@c)[0];

one        three      six
two        four       seven
           five
[download]

Or generalized as a subroutine

#! perl -slw
use strict;

sub pa_columns{
    my $fmt = shift;
    printf( ($fmt x @_).$/ , do { my $n=$_; map{ $_->[$n] || '' } @_; 
+} )
        for 0 .. ( sort{ $b<=>$a } map{ $#$_ } @_ )[0];
}


my @a = qw[one two];
my @b = qw[three four five];
my @c = qw[six seven];

pa_columns '%-10s ', \(@a, @b, @c);

my @d = 1 .. 10;
my @e = 'A' .. 'G';
print $/;
pa_columns '%5.5s ', \(@d, @e, @a, @b, @c);

__DATA__
C:\test>pa_cols
one        three      six
two        four       seven
           five


    1     A   one three   six
    2     B   two  four seven
    3     C        five
    4     D
    5     E
    6     F
    7     G
    8
    9
   10
[download]