One key change I'd suggest is to set your subs up so that they accept parameters and return values rather than relying on global variables directly. This is good habit to develop for a lot of reasons, and it will definitely pay off as you start to develop produce larger programs. For instance, you might rewrite Get_MDs like this:

sub Get_MDs
{
    my ($mds) = @_;
    my @results;
    foreach $key (keys (%{$mds->{md}})) {
        push(@results, $mds->{md}->{$key}->{'name'} . $key);
    }
   return @results;
}
[download]

my @mds = Get_MDs($mdlist);
[download]

It would also be a good idea to pass a directory name to checkdir explicitly, rather than relying on it to use the current value of $_.

Second, you're using map in a way that's considered less than ideal. map's purpose is to perform a function on each element of a list and construct a list from the results. So a typical use of map might look something like this: my @squares = map {$_**2} @numbers; In your code above, you're simply throwing away the results; a better alternative would be to replace map with a for construct:

checkdir($_) foreach (@mds)
[download]

Finally, I'd be inclined to replace your print "error"; exit code blocks with a single die "error" statement. die will direct output to STDERR rather than STDOUT and will terminate the program with a non-zero exit code, both of which can be useful if you want to execute the program from within another script (Perl or shell or otherwise).

Since die is a single command, it also lends itself to the following idiom:

die "problem: $@" if $@;
[download]

        $perlmonks{seattlejohn} = 'John Clyman';

#!/usr/bin/perl -w
use strict;

use XML::Twig;

my $callout_loc = ".";
my $file = "./mdlist.xml";

#create the parser (twig)
#and tell it what sub to call if it finds an 'md' element
my $twig = new XML::Twig (twig_handlers => {md => \&process_md});

#parse the file
#process_md will be called every time an 'md' element is found
$twig->parsefile ($file);

#that's it
exit 0;

sub process_md {
    my ($t, $md) = @_;

    #get the name attribute
    my $name = $md->att ('name');
    
    #create the dir unless it already exists
    my $dirname = "$callout_loc/$name";
    unless (-d $dirname) {
        print "Creating $dirname...\n";
        mkdir $dirname or die "Could not create dir $dirname: $!\n";
    }
    else {
        print "$dirname already exists!\n";
    }
}
[download]

pike

As some-one who has had NO formal programming training, I face this issue often. I have just written some code and tested it successfully. I manage to get perl to do what I need it to. What ALWAYS concerns me though, is that I am never confident in whether or not my code is "Best Practice" (for lack of a better expression). I mean are there better ways of doing certain things...?

Welcome to the club. Those who say they know are those who never learn something new.

-- Randal L. Schwartz, Perl hacker
Be sure to read my standard disclaimer if this is a reply.

24 hours later....

use strict;
use warnings;
use XML::XPath;

my $xp  = XML::XPath->new(filename => 'mdlist.xml');
my @mds = map { 
   $_->getAttribute('name') 
} $xp->findnodes('/md_map/md[@name]');


for my $dir (@mds) {
   # create $dir if applicable
}
[download]

One thing to note -- you are relying upon your script being executed from a particular directory in order for it to work. Not good. Instead, use absolute paths to the files:

my $callout_loc = '/path/to/xml/stuff';
my $file        = "$callout_loc/mdlist.xml";
[download]

mkdir $dir or warn "$dir already exists: $!";
[download]

jeffa

L-LL-L--L-LL-L--L-LL-L--
-R--R-RR-R--R-RR-R--R-RR
B--B--B--B--B--B--B--B--
H---H---H---H---H---H---
(the triplet paradiddle with high-hat)