I could not find how to read back a dumped file

use Data::Dumper;

my %hash = qw( foo one bar two baz three );

open  DATA, ">whatever.dat";
print DATA Dumper(\%hash);
close DATA;

my %hash2 = %{ do "whatever.dat" };
print Dumper(\%hash2);

__output__

$VAR1 = {
          'foo' => 'one',
          'baz' => 'three',
          'bar' => 'two'
        };
[download]

_________
broquaint

That it was that simple after all. This is doing the job except for one thing. If your hashtable contains a non-referenced top level it will be removed during the input using do. See sample below

Original hash table

$VAR1 = 'dataParams';
$VAR2 = {
          'license_feature' => {
                                 'val' => 'geditor'
                               },
                  };
[download]

New hash table

$VAR1 = 'license_feature';
$VAR2 = {
          'val' => 'geditor'
        };
[download]

So it is not exactly the same but it already helps a lot.

Try using the Dump function of Data::Dumper like this:

use Data::Dumper;
my %hash2 = (
    some => "really",
    complicated => ["hash", ["structure"]]
);
print Data::Dumper->Dump([\%hash2], ['*hash2']);
[download]

this prints out:

%hash2 = (
           'some' => 'really',
           'complicated' => [
                              'hash',
                              [
                                'structure'
                              ]
                            ]
         );
[download]

writing to a file and do()ing it is left as an exercise

--

flounder

If you're going to be using a simple do() then you need to pass a reference to Dumper() as passing a bare hash results in a list of values being dumped which is not what you want e.g

use Data::Dumper;

my %hash = ( 'dataParams', {
               'license_feature' => { 'val' => 'geditor' }
             } );


open  DATA, ">whatever.dat";
print DATA Dumper(%hash);
close DATA;

print "bare hash dump\n", Dumper(do "whatever.dat");

open  DATA, ">whatever.dat";
print DATA Dumper(\%hash);
close DATA;

print "reference dump\n", Dumper(do "whatever.dat");

__output__

bare hash dump
$VAR1 = {
          'license_feature' => {
                                 'val' => 'geditor'
                               }
        };
reference dump
$VAR1 = {
          'dataParams' => {
                            'license_feature' => {
                                                   'val' => 'geditor'
                                                 }
                          }
        };
[download]

So as you can see when you dump by reference you get back the complete data structure.
HTH

_________
broquaint

You are saying listify the hash first ala

print Dumper(%hash);
[download]

When you should be saying dump the hash as a reference

print Dumper(\%hash);
[download]

But as someone said, if you want to dump several top level vars and get them back in a list form

$dump= Data::Dumper->Dump([[\%hash,\@array,$scalar]],[qw(*vars)]);
my @vars=eval $dump;
[download]

theres a few other tricks as well. You can parse out the var names from dumper then wrap them all in a do and return them as a list, yada yada.

A last point. You may want to dump in Pruity=1 mode.

$Data::Dumper::Purity=1;
print Data::Dumper->new([\%foo],['*foo'])->Purity(1)->Dump;
[download]

Be aware that seriously sick and twisted data structures dont dump properly with Data::Dumper. For this reason unless hand modification is needed of the dumped data you should use Storable instead. Also, evaling these structres from a file is a serious security risk (hostile code can be embedded in the file and will execute with your permissions when you eval it). Another good reason to use Storable (which has an easy to use reader too.)

Anyway,

--- demerphq
my friends call me, usually because I'm late....

my $ref = eval $data;
[download]