I'm glad to see that you're using strict.pm.

Your code is overcommented. Stuff like:

my $median_class_avg;    #-- median class average
...
#-- Open the input file 
open(INPUT, '<', $input_file) or die "Couldn't open $input_file: $!\n"
+;
...
   #-- Print student's average
   printf "%5.1f%2s", $students{$name}{avg_grade};
[download]

is worse than redundant: it's distracting, and if the code changes, it's a good bet that the comment won't (which is pretty confusing to all concerned). Your code's pretty well written anyways, so you can probably just remove most of the comments without harming readability.

This loop could be rewritten from

   foreach ( 0 .. $#{ $students{$name}{grades} } )
   {
      printf "%4d", $students{$name}{grades}[$_];
   }
[download]

to

  foreach $grade (@{$students{$name}{grades}}) {
    printf "%4d", $grade;
  }
[download]

which is not only clearer, but avoids indexing errors.

Actually, that brings up a good point: I find it easier to pull out nested references explicitly, like so:

  my @grades = $students{$name}{grades};
  foreach my $grade (@grades) {
    printf "%4d", $grade;
  }
[download]

Those complaints aside, this is pretty well-written code.

--
F o x t r o t U n i f o r m
Found a typo in this node? /msg me
The hell with paco, vote for Erudil!

There's a subtle bug in the sorting trick you used, sorting on "$last,$first". The inserted comma can throw off the sort, as in the following:

my @names = ("O'Toole,Peter",
             "O,Ari");
my @sorted = sort @names;
print join(";",@names),"\n";
[download]

To get the correct sort order, you need something like this:

my @names = (["O'Toole","Peter"],
             ["O", "Ari"]);
sub namesort {
    $a->[0] cmp $b->[0] or $a->[1] cmp $b->[1]
}
sub namejoin {
    return join(",",@{$_[0]});
}
my @sorted = sort namesort @names;
print join(";",namejoin($sorted[0]),namejoin($sorted[1])),"\n";
[download]

Firstname Lastname list_of_grades(any number of grades)

Hence, you need to check to make sure a student has at least 1 grade before trying this division:

$students{$name_index}{avg_grade} /= scalar(@{ $students{$name_index}{
+grades} });
[download]

teachers are sneaky at times (or so experience would tell me). all else looks good though.

-enlil

My mistake. The assignment allowed us to assume that each student had at least one grade, otherwise I would have done exactly as you suggested.

Thanks,
Inelukii

1) ++inelukii for posting homework...after the fact, so to speak. As already mentioned, there are enough sharps in your code to make the eyes bleed, and for the most part are commenting code that is pretty obvious.

foreach (0.. $#(somearray) ) can be a real drag sometimes, and almost always better written as foreach my $element (@array) unless you absolutly need the numeric index. Out of interest, how were you marked for this assignment?

Received 100 for the assignment and an extra 5 points for the shortest solution. ;)
As far as all the comments go, I apologize, but you just have to know this professor. It annoys me more than anything the amount of commenting we have to do. Thanks for the kind words so far.

Inelukii

I had my suspicions that the comments were for the benefit of your prof. Interesting aside: A colleague turned in several assignments in uni as pseudo code, splattered with comments, after 'learning' the prof never ran the student assignments! May the karma catch him eventually

I'd restructure the loop for reading in the input file a bit:

use List::Util qw/sum/;

while( <INPUT> )
{
  next if /^$/;
  my ($first, $last, @grades) = split;

  my $name_index = "$last,$first";
  my $avg_grade = sum(@grades) / scalar(@grades);

  $students{$name_index}{grades}    = \@grades;
  $students{$name_index}{avg_grade} = $avg_grade;

  push @averages, $avg_grade;
}
[download]

I don't know whether you are allowed to use modules to solve your exercise - but the sum subroutine from List::Util comes in handy here. Otherwise you could just program the sub yourself. I don't see any point in rounding the results you push into @averages. You are only using this internally and why not calculate with the whole precision you have available - thus simplifying the code. You could still do the rounding when you print something out.

A final remark to a differnt part of the code, this: my $i = sprintf("%d", scalar(@averages) / 2 ); could be better written as my $i = int( scalar(@averages)/2 ); Both do rounding towards zero.

-- Hofmator

This is well written for a student IMO. I'd agree that it's overly micro-commented, but I also recall that I did that in college because most professors preferred it to under commenting. I had a friend whose style I'm much closer to today -- well named variables, minimal line level comments, block comments to describe major areas, and overall package docs. He got points taken off for fewer line level comments which really is not fair (and a poor reflection on the prof). But if you're going for the grade you're more likely to do better with more than less.