use strict;
open INPUT, "<myfile.txt" or die "Could not open input file: $!\n";
open OUTPUT, ">output.txt" or die "Could not open output file: $!\n";
my $count=0;
while (<INPUT>)              # Loop over lines of file
{ 
next unless ($. > 2);        # Ignore first two lines
s/do my/replacement/ if ($. == 3);
print OUTPUT $_;             # Print to output file.
}
close INPUT;
close OUTPUT;
[download]

Line 1
Line 2
Line 3 do my
Line 4

Line 3 replacement
Line 4

CU
Robartes-

To add to what robertes says, if you want to put the output of the program back over the input file (as you apparently do), you can use the -i flag of perl:

#!/usr/bin/perl -w -i.bak
use strict;
while (<>)              # Loop over lines of file
{ 
  next unless ($. > 2);        # Ignore first two lines
  s/do my/replacement/ if ($. == 3);
  print $_;
}
[download]

Then you can perl edit.pl myinput, which will move the input file to myinput.bak and put the output back in myinput

It's quite simple really, but if it's your first script, I'm sure it seems very difficult. /me remembers the first scripts he ever wrote and shudders. Something like this might help, assuming that by 'replace the third line' you mean delete it and place something else there:

#!/usr/bin/perl -Tw
use strict;

my $file = 'data.txt';
my $fh;

open $fh, '<', $file
 or die "Could not open $file for read: $!";
chomp( my @lines = <$fh> );
close $fh;

@lines = ('Replace line 3 with this', @lines[3..$#lines]);

open $fh, '>', $file
 or die "Could not open $file for write: $!";
print $fh join("\n", @lines);
close $fh;
[download]

Update: If by 'replace the third line', you meant execute a regex to do a 'search and replace' type of thing, then you can modify my above code to something more along these lines:

#!/usr/bin/perl -Tw
use strict;

my $file = 'data.txt';
my $fh;

open $fh, '<', $file
 or die "Could not open $file for read: $!";
chomp( my @lines = <$fh> );
close $fh;

$lines[2] =~ s/foo/bar/g;
@lines = (@lines[2..$#lines]);

open $fh, '>', $file
 or die "Could not open $file for write: $!";
print $fh join("\n", @lines);
close $fh;
[download]

If the above content is missing any vital points or you feel that any of the information is misleading, incorrect or irrelevant, please feel free to downvote the post. At the same time, reply to this node or /msg me to tell me what is wrong with the post, so that I may update the node to the best of my ability. If you do not inform me as to why the post deserved a downvote, your vote does not have any significance and will be disregarded.

There is a really nice and simple-to-use module called Tie::File, which allows you to access a file as if it were a perl array :

use strict;
use Tie::File;
my @file;
my $filename = 'test.txt';
tie @file, 'Tie::File', $filename
  or die "Couldn't open '$filename' : $!\n";

die "The second line in '$filename' is not blank !\n"
  unless $file[1] eq '';

# Remove first line :
shift @file;

# Remove second line :
shift @file;

# Replace first (former third) line :
$file[0] = "New text";
[download]

perl -MHTTP::Daemon -MHTTP::Response -MLWP::Simple -e ' ;    # The  
$d = new HTTP::Daemon and fork and getprint $d->url and exit;#spider
($c = $d->accept())->get_request(); $c->send_response( new   #in the
HTTP::Response(200,$_,$_,qq(Just another Perl hacker\n))); ' #  web
[download]

I assume you've already set up your script to read the file and write the changed results somewhere else. Something like this if you were reading from standard input and writing to standard output:

while (<>)
{
    # edit line if needed.
    print $_;
}
[download]

my $line = 0;
while (<>)
{
    ++$line;
    next if ($line < 3);          # skip first two lines
    s/XXXX/YYYY if ($line == 3);  # change third line
    print $_;
}
[download]

  #!/bin/perl -ni.bak
  print $. < 3 ? () : $. > 3 ? $_ : "new third\n";
[download]

  #!/bin/perl -ni.bak
    print
  } BEGIN {
    scalar <>; scalar <>; scalar <>;
    print "This text replaces the third line.\n";
  } {
[download]

jdporter
The 6th Rule of Perl Club is -- There is no Rule #6.