Since the numbers in the left hand column are unique and are the keys to your searches, you could load the data file into a hash instead of an array. Your answer then comes from a direct hash lookup rather than having to search.

#!/usr/bin/perl -w
use strict;
my %kids=map { split } <DATA>;
print "Father of $_ is $kids{$_}\n" for @ARGV;

__DATA__
1045316394 1045316144
1045316407 1045316394
1045316419 1045316407
1045316438 1045316419
1045316469 1045316394
1045316492 1045316407
1045316505 1045316492
[download]

Example usage:

$ perl fatherson.pl 1045316419 1045316492
Father of 1045316419 is 1045316407
Father of 1045316492 is 1045316407
[download]

Of course, you should add some code to do something sensible if the requested child is not found.

Update: You want the full lineage. You could do something like this.

sub print_lineage {
    my ($x) = @_;
    my @p;
    while (exists $kids{$x}) {
    $x = $kids{$x};
    push @p,$x;
    }
    if (@p) {
    local ($") = ", ";
    print "Lineage of $_[0] is @p\n";
    } else {
    print "Lineage of $_[0] is unknown\n";
    }
}
print_lineage $_ for @ARGV;
[download]

Which produces:

$ perl fatherson.pl 1045316419 1045316469
Lineage of 1045316419 is 1045316407, 1045316394, 1045316144
Lineage of 1045316469 is 1045316394, 1045316144
[download]

---
print map { my ($m)=1<<hex($_)&11?' ':'';
$m.=substr('AHJPacehklnorstu',hex($_),1) }
split //,'2fde0abe76c36c914586c';
[download]