sub grep2d {
  my($ar, $el) = @_;
  grep { grep $el == $_, @$_ } @$ar;
}

use Data::Dumper;
my $array = [ [ 1 .. 3 ], [ 4 .. 5 ], [ 3 .. 5 ] ];
print Dumper( grep2d($array, 3) );

__output__

$VAR1 = [
          1,
          2,
          3
        ];
$VAR2 = [
          3,
          4,
          5
        ];
[download]

_________
broquaint

Nice one.. for completeness, here's a version that allows arbitrary tests:

sub grep2d (&;@) {
        my $test = shift;
        grep { grep $test->(), @$_ } @_
}

use Data::Dumper;
my @array = ( [ 1 .. 3], [ 4 .. 5 ], [ 3 .. 5 ] );
print Dumper grep2d { $_ == 3 } @array;
[download]

Note that this can likely be done more efficiently: the inner grep tests all elements, while we only care about whether or not one element matches. But unless the rows are very large, it probably doesn't matter.

For this, you will need to loop over your array - using both indices - something like the following untested code:

#!/usr/bin/perl -w
use strict;
my @array = (); #actually use code that creates 2d array
for ( my $i = 0; $i <= $#array; $i++) {
   for ( my $j = 0; $j <= $#{$array[$i]}; $j++ ) {
       if ($array[$i][$j] =~ /something/) {
           # Do something with $array[$i][$j]
       }
   }
}
[download]

Hope this helps point you in the right direction. I really like our Q/A section at PM, the http://www.perlfaq.com FAQ, and the http://www.perldoc.com FAQ.

Cheers - L~R

Update: Code now tested. As others have shown, if you do not need the indices and need only the row - other methods work with grep.

my @two_d = (
        [qw( foo bar baz)],
        [qw( bar baz quux)],
        [qw( baz quux foo)]
        );
my @rows = grep { grep {/foo/} @$_ } @two_d;
[download]

You get a 2-d array containing only the rows matching 'foo'.

After Compline,
Zaxo