#!/usr/local/bin/perl
# repl.pl
use strict;
open INPUT, "<input.txt" or die "Blerch: $!\n";
open OUTPUT, ">output.txt" or die "Hcrelb: $!\n";
my $replace_string="Hi there.\n";
my $flag=0;
my %markers=("BEGIN" => "<!- Begin Replacable Section-->",
             "END" => "<!- End Replacable Section-->",
            );
while (<INPUT>) {
  if ($flag) {
    next unless /$markers{END}/;
    $flag=0;
    print OUTPUT $replace_string;
  }
  print OUTPUT;
  $flag=1 if /$markers{BEGIN}/;
}
__END__
> cat input.txt
But now I know that twenty centuries of stony sleep
were vexed to nightmare by a rocking cradle.
And what rough beast, it's hour come round at last,
slouches towards Betlehem to be born?
<!- Begin Replacable Section-->
A poem
<!- End Replacable Section-->
W. B. Yeats

> repl.pl ; cat output.txt
But now I know that twenty centuries of stony sleep
were vexed to nightmare by a rocking cradle.
And what rough beast, it's hour come round at last,
slouches towards Betlehem to be born?
<!- Begin Replacable Section-->
Hi there.
<!- End Replacable Section-->
W. B. Yeats
[download]

CU
Robartes-

You'll probably want to do this:

   next unless /\Q$markers{END}\E/;
[download]

and the same for the other pattern match. This ensures that your markers string gets seen as a literal string to match, not as a pattern itself. Especially if you are using < and > which tend to have meanings within regexes.

dave hj~

This assumes that your sections start and end on seperate lines...if that's not the case an slightly different version is required. See perlman:perlrun for the details of the switches.

On a *nix system you don't need the first line of the BEGIN{} block

#! perl -snli.org
use strict;
use vars qw[$B $E $R $s];
BEGIN{
    @ARGV= map{glob}@ARGV; # Not necc. on *nix
    $s=0
}

    /<!- $B -->/ .. (/<!- $E -->/ && ($s = 1))
    ? ($s and print($R), $s = 0 )
    : print
[download]

sample usage

The alternative is the suggestion by the other poster - run through each line and use a flag to tell you whether you are in a replaceable section.

The more awkward problem is how to replace the text in the file. Again, it is perfectly valid to just open an INPUT filehandle and an OUTPUT filehandle, then to rename the new file to overwrite the old one. However, that is quite complex. A neater idea might be to write a shell script and use some of perl's command line switches. (See perlrun for details.) Something like:

find . -name *.ext -print | xargs perl -pi.bk -e \
'
if ($flag && /end_match/) {$flag = 0;}
if ($flag) {
    $sub = $printed++? '': 'My text to substitute';
    s/^.*$/$sub/;
}
if (/start_match/) {$flag++;$printed = 0;}
'
[download]

No good if you're on windows though...

dave hj~

use File::Temp qw(tempfile);
use Cwd;

sub replace_file {
 my ($file, $start, $end, $replace_text) = @_;
 local (*ARGV, $_, $.); @ARGV = $file;
 my ($fh, $tmp_file) = tempfile(DIR=>cwd);
 my $replaced;
 while (<>) {
   my $replace = /\Q$start\E/../\Q$end\E/;
   print $fh $_ and next unless $replace;
   $replaced=1;
   print $fh $replace_text if $replace == 1;
 }
 close $fh;
 return unless $replaced;
 rename $tmp_file, $file or warn "Error replacing $file: $!";
}
[download]

Thank you all for the great help. The markers are not the only text on the line. For example one of the file has these lines: "<\td class="health" height="99%"> <-- #BeginEditable "category" class="category" -->MEDICAL {carriage return} BENEFITS</\td></\tr> <\tr valign="top"> <\td height="99%" class="mainbody"> " (The extra slashes are to display the html code as is) The beginning marker for this is <-- #BeginEditable "category" class="category" --> and the ending marker for this is <-- #EndEditable --> i.e. I have to discard everthing after the beginning marker but not the marker or any thing before itself. I have to discard everything before the end marker but not the end marker or anything after that. I think I will try figuring this out myself. If anybody can find some time to post the code, I would be greatful. Thank You for the great help.