mapping two arrays into a hash

Anonymous Monk has asked for the wisdom of the Perl Monks concerning the following question:

I have two arrays that have the same number of elements and each element of the first array corresponds to the same number element in the second. I used the following bit of code to put them into a hash, but there has to be a neater way of doing so.

#!/usr/bin/perl -w
use strict;

my @array1 = qw(a b c);
my @array2 = qw(1 2 3);
my %hash;

for(0..$#array1){
  $hash{$array1[$_]}=$array2[$_];
}
[download]

How would I use map to accomplish the same thing?

Comment on mapping two arrays into a hash Download Code

Replies are listed 'Best First'.
(z) Re: mapping two arrays into a hash by zigdon (Deacon) on Feb 26, 2003 at 20:52 UTC
Why use map when a slice would do? `@hash{@array1} = @array2;` [download] -- zigdon	[reply] [d/l]
Re: mapping two arrays into a hash by tachyon (Chancellor) on Feb 26, 2003 at 21:10 UTC
A slice is the go but TIMTOWDI `# slice @hash{@ary1} = @ary2; # map %hash = map { $ary1[$_], $ary2[$_] } 0..$#ary1;` [download] cheers tachyon s&&rsenoyhcatreve&&&s&n.+t&"$'$`$\"$\&"&ee&&y&srve&&d&&print	[reply] [d/l]
Re: mapping two arrays into a hash by integral (Hermit) on Feb 26, 2003 at 21:12 UTC
Zigdon's answer shows the very simple (and good) way to do it, but as you ask you can do this using map to interleave the two arrays (this might be useful for other data structures too). `my (%hash, @a, @b); %hash = map { ($a[$_], $b[$_]) } 0..$#a;` [download] Update: This is the same as tachyon's code. Although as always TMTOWTDI applies, and you can do it with other loops, although the one below is destructive: `my (%hash, @a, @b); $hash{shift @a} = shift @b while (@a and @b);` [download] -- integral, resident of freenode's #perl	[reply] [d/l] [select]
Re: mapping two arrays into a hash by OM_Zen (Scribe) on Feb 26, 2003 at 22:05 UTC
Hi , `#This is with map as both arrays are of same length %hashofarray = map { $array1[$_] => $array2[$_] }0..$#array1; #This is a way to use arrays for building hash @hashofarray{@array1} = @array2;` [download]	[reply] [d/l]