in reply to Advice for moving forward with modules

When you call die from inside a module, you should probably be using croak instead (and carp instead of warn). These two methods are available from Carp.pm. Try this little exercise, save the following as Foo.pm: 
package Foo;

use Carp qw(croak);
use base qw(Exporter);
our @EXPORT_OK = qw(gonna_croak gonna_die);

sub gonna_die   { die "ya got me!" }
sub gonna_croak { croak "ya got me!" }

1;

[download]
Now use that module with the following one-liners: 

$ perl -MFoo=gonna_die -le gonna_die
ya got me! at Foo.pm line 7.

$ perl -MFoo=gonna_croak -le gonna_croak
ya got me! at -e line 1
die reports the error from the actual line it was executed on, which might be many packages deep. croak, on the other hand, reports the error from the perpestive of the caller, which is usually more useful to the end user. The end user usually cares more about which line of their code caused the problem, not which line in the module it affected.

jeffa

L-LL-L--L-LL-L--L-LL-L--
-R--R-RR-R--R-RR-R--R-RR
B--B--B--B--B--B--B--B--
H---H---H---H---H---H---
(the triplet paradiddle with high-hat)

Replies are listed 'Best First'.
Re: (jeffa) Re: Advice for moving forward with modules
by tachyon (Chancellor) on Feb 28, 2003 at 00:16 UTC

    I like the full confession myself rather than croak. Sure you get some cake you may not want to eat but you get the whole cake! 

    use Carp;

hello();

sub hello { again() }
sub again { my_friend() }
sub my_friend { I() }
sub I { called() }
sub called { to_say()}
sub to_say { confess('Goodbye, I died') }

__DATA__
Goodbye, I died at script line 10
    main::to_say() called at script line 9 
    main::called() called at script line 8 
    main::I() called at script line 7
    main::my_friend() called at script line 6
    main::again() called at script line 5
    main::hello() called at script line 3

    [download]

    cheers

    tachyon

    s&&rsenoyhcatreve&&&s&n.+t&"$'$`$\"$\&"&ee&&y&srve&&d&&print

[reply]
[d/l]

In Section Meditations