while (<FILE>) {
    if (/foo/) {
        $count++;
        print "$count so far.\n";
    }
}
[download]

while (<FILE>) {
    while (/foo/g) {
        $count++;
        print "$count so far.\n";
    }
}
[download]

while (<FILE>) {
 $count++ while /foo/g; 
}
print $count;
[download]

-enlil

Or something slightly different yet the same

while ( <FILE> ) {
   $count += $_ =~ s/foo/foo/g;
   print "$count so far\n";
}
[download]

If you do $count = $_ =~ s/foo/foo/g; $count will have how many replacements happened on that line. Instead of using a temp variable to hold it, I simply += it as we go.. I should probably benchmark it to see how it compares, but its late.

/* And the Creator, against his better judgement, wrote man.c */

Hey, wow -- cool stuff, works perfectly. Great response time :)

Can you explain why this made it work? I think I get why the global bit was necessary for the regex (otherwise, it wouldn't check the whole file); however, why did using while instead of if make a difference?

Another way you could do this:

while (<FILE>) {
     $count += () = m/foo/g
}
print $count;
[download]

But back to the way this:

while (<FILE>) {
    while (/foo/g) {
        $count++;
        print "$count so far.\n";
    }
}
[download]

works is that the inner while will continue to evaluate $_ =~ /foo/g, (which is the lengthier version of: /foo/g ), anyhow it will continue to evaluate it until it has no more matches. So it will find the first foo then stop update the count, and then return to the search beginning where it left off, and so forth until it finds no more matches, but adding one to count each time it does find one. (I hope I am not confusing you further).

The if does not work because it only cares if the expression in the parens returns a true or false value. Strings with foo are true, add one to your count and on to the next line. (strings without foo are false of course). You could do something like the following:

my $count;
while (<FILE>) {
   if ( $count += s/foo/foo/g ) { print "$count so far\n" )
}
[download]

Here the s/foo/foo/g returns the number of times it replaces foo with itself adds it to the count, and the number it returns is also the number the if checks for truth ( so a line like "foo foo foo" would be evaluated as if (3), as opposed to whether or not the addition to $count was successful.)

anyhow I hope I was some help, it is late and i tend to ramble anyhow.

oh yeah, ++ for asking for an explanation instead of just taking code without understanding it (and having to explain it often times makes me wonder if I understand it myself).

-enlil

What he did is perform another loop, with each iteration happening everytime the regex matched in the string...
Ala

@test = ('foobarfoo', 'blahbarblah', 'bazbarbarbarbaz');

while (@test) {
#
# $_ has foobarfoo or blahbarblah or bazbarbarbarbaz
#
   while(/bar/g) {
#
# matched bar once in foobarfoo inc by 1 
# matched bar once in blahbarblah inc by 1
# matched bar 3 times in bazbarbarbarbaz inc by 1 3 times
#
      $count++;
      print "$count so far\n";
   }
}
[download]

Edit: Sorry for replicating information, Enlil and myself were probably typing at the same time..


/* And the Creator, against his better judgement, wrote man.c */

use strict;
use warnings;

my $file = do { local $/; <> };

my $count = 0;

++$count while $file =~ /foo/g;

print $count;
[download]

Enlil already gave the good explanation of the next lines and this works in the same way for one line and for a whole file. In this context it might be interesting for you to look up the /m and /s modifiers for regexes.

-- Hofmator