my @arr = (['a','b','c'],
           ['h','i','j'],
           ['x','y','z']);

print map $_->[1], @arr;

__output__

biy
[download]

_________
broquaint

There are two way of looking at what constitutes a slice of a 2d array--and more for higher dimensions:)

In the first veiw, the result is what you would get if you could notionally extend perl's @arr[n..m] syntax to a 2D array: @arr[*][n..m] which might be described as "Give me a new 2d array where each row consists of just the columns n through m of the original array". For your example array, and with n & m set to 1 & 2 respectively, this would result in

my @vslice = (['b','c'],
              ['i','j'],
              ['y','z']);
[download]

The second view, and the one you want, is where the resultant arrays row(s) become 1 (or more) column(s) from the original array. for the same example as above you get

my @yxslice = ( ['b','i','y'],
                ['c','j','z'] );
[download]

Two functions to produce these

#! perl -slw
use strict;
use Data::Dumper;

sub vslice  {
    map{
        [
            @{$_}[@_]
        ]
    } @{+shift};
}

sub yxslice {
    my $aref = shift;
    map{
        my $i=$_;
        [
            map{
                $_->[$i]
              } @$aref
        ]
    } @_;
}

my @arr = (['a','b','c','d'],
           ['h','i','j','k'],
           ['w','x','y','z']);


my @vslice = vslice \@arr, 1..2;
print Dumper \@vslice;

my @yxslice = yxslice \@arr, 1..2;
print Dumper \@yxslice;

__END__
C:\test>240941
$VAR1 = [
          [ 'b', 'c' ],
          [ 'i', 'j' ],
          [ 'x', 'y' ]
        ];

$VAR1 = [
          [ 'b', 'i', 'x' ],
          [ 'c', 'j', 'y' ]
        ];
[download]

I would use these versions of the two functions as it simplifies the syntax of using them slightly, but prototypes are almost universally condemned.

sub vslice  (\@@) { map{ [@{$_}[@_]] } @{+shift}; }
sub yxslice (\@@) { 
    my $aref = shift; 
    map{ my $i=$_; [ map{ $_->[$i] } @$aref ] } @_; 
}
[download]

my @arr = (['a','b','c'],
           ['h','i','j'],
           ['x','y','z']);

my @first_column = map $_->[0], @arr;
[download]

my @arr = (['a','b','c'],
           ['h','i','j'],
           ['x','y','z']);

for (map $_->[0], @arr) {
   # $_ now holds the current value of column 1 (index 0)
}
[download]