in reply to Re: Perl 6 is too complex
in thread Perl 6 is too complex

I converted that Perl 6 code to Perl 5 best I could and came up with
Here's a slightly more direct conversion 
sub apply(&@) {
  ## ack, Class::Multimethods doesn't do variadic args :-/
  return if @_ == 1;

  my($func, $head, @tail) = @_;
  local $_ = $head;
  return $func->(), apply($func, @tail);
}

my @squares = apply { $_ * $_ } 2 .. 5;

print join(', ', @squares), $/;

__output__

4, 9, 16, 25

[download]
As the comment gives away, this isn't a direct conversion as it isn't using multimethods, so it uses an arg count hack to emulate the behaviour. Also to be an even closer conversion would require apply to tie @squares to a square generator (at least I think that's probably the closest thing you can get to binding to a lazy list in perl6 with raw perl5). So it's certainly no easy task to convert that wee but powerful snippet directly to perl5!
HTH

_________
broquaint

Replies are listed 'Best First'.
Re: Re: Re: Perl 6 is too complex
by broquaint (Abbot) on Mar 17, 2003 at 11:55 UTC
    Also to be an even closer conversion would require apply to tie @squares to a square generator
    Ok, perhaps not a square generator, but maybe something like this 
    use strict;

{
  package Tie::Array::Apply;

  use overload
    '@{}'    => sub { $_[0]->{list} },
    fallback => 1;

  use Tie::Array;

  @Tie::Array::Apply::ISA = qw( Tie::StdArray );

  sub TIEARRAY {
    my $class = shift;

    bless { func => shift, list => [@_], array => []}, $class;
  }

  sub FETCH {
    my($self,$pos) = @_;

    return $self->{array}->[$pos]
        if exists $self->{array}->[$pos];

    return undef
        if $pos >= @{ $self->{list} };

    local $_ = $self->{list}->[$pos];
    return $self->{array}->[$pos] = $self->{func}->();
  }
}

sub bind_apply(&@) {
  tie my @ret, 'Tie::Array::Apply', @_;
  return @ret;
}

my @bind_squares = bind_apply { $_ * $_ } 2 .. 5;

print "bind_apply: ", join(', ', @bind_squares), $/;

__output__

bind_apply: 4, 9, 16, 25

    [download]
    That code will lazily evaluate a list where each indice is bound to a function which has the appropriate element in the initial list applied to it. But now it doesn't have the recursive behaviour demonstrated in the original perl6 function so no longer needs a funky prototype or multimethod dispatch. Ho hum.
    HTH

    _________
    broquaint

[reply]
[d/l]

In Section Meditations