in reply to File::Find problem

As I've just been ranting in another thread: callbacks aren't a great interface (to say the least).

I find File::Find so quirky to use that it usually takes me less time to write my own directory scanner than it does to figure out how to get File::Find to do what I want. Sure, for simple "do this to nearly every file" operations, File::Find can save me time. But for those I tend to use /bin/find instead anyway (from cygwin or find2perl if needed).

There are a few classic mistakes you need to keep in mind when searching a directory tree:

So here is my way of doing it which I think is much more natural: 
#!/usr/bin/perl -w

use strict;

Scan( '/home/greg/mydir' );

sub Scan {
    my( $dir, $path )= @_;
    $path ||= ".";
    chdir $dir
        or  die "Can't chdir($dir) from $path: $!\n";
    $path= $dir   if  "." eq $path;
    my @files= (
        glob("*"),
        grep
            "." ne $_  &&  ".." ne $_,
            glob(".*")
    );
    for my $sub (  grep ! -l $_ && -d _, @files  ) {
        Scan( $sub, "$path/$sub" );
    }
    if(  grep /\.old$/, @files  ) {
        local( @ARGV )= "CPB";
        local( $^I )= ".old";
        while(  <>  ) {
            if(  /^cat/  ) {
                print "cat\t/kat/src/all/b-ld_pipe.4go \\\n";
                s/^cat\t/\t/;
            }
            print;
        }
    }
    chdir "..";
}

[download]

                - tye

Replies are listed 'Best First'.
Re: Re: File::Find problem (yucky callbacks)
by zby (Vicar) on Mar 19, 2003 at 08:45 UTC
    There is File::Iterator, I have not used it yet, but it seems to simplify things.
[reply]

      Actually, I've been thinking about this and I think my preferred interface might be an object that lets you iterate in several directions so you can pick depth-first or bredth-first and decide to prune your search in what I consider more natural ways: 

      # The simple case like File::Find / File::Iterator
    my $iter= File::Whatever->new( $root );
    while(  $iter->NextItem()  ) {
        doSomething( $iter->GetFileName() );
    }

# Recurse yourself:
    my $iter= File::Whatever->new( $root );
    MyFunc( $iter );
    sub MyFunc {
        my $iter= shift(@_);
        # Uncomment next line for depth-first search:
        MyFunc( $iter )   while  $iter->PushPath();
        while(  my $file= $iter->NextFile()  ) {
            doSomething( $file );
        }
        # Uncomment next line for bredth-first search:
        #MyFunc( $iter )   while  $iter->PushPath();
        $iter->PopPath();
    }

# Example of pruning your search:
    my $iter= File::Whatever->new( $root );
    MyFunc( $iter );
    sub MyFunc {
        my $iter= shift(@_);
        while(  my $file= $iter->NextFile()  ) {
            doSomething( $file );
        }
        while(  my $sub= $iter->PushPath()  ) {
            if(  $sub =~ /debug/i  ) {
                $iter->PopPath();
            } else {
                MyFunc( $iter );
            }
        }
        $iter->PopPath();
    }

# Bredth-first search w/o recursion:
    my $iter= File::Whatever->new( $root );
    do {
        while(  my $file= $iter->NextFile()  ) {
            doSomething( $file );
        }
    } while(  $iter->NextPath()  );

# Bredth-first search w/ pruning w/o recursion:
    my $iter= File::Whatever->new( $root );
    do {
        while(  my $file= $iter->NextFile()  ) {
            doSomething( $file );
        }
        while(  $iter->NextPath() =~ /debug/i  ) {
            $iter->PopPath();
        }
    } while(  ! $iter->Finished()  );

# Depth-first search w/o recursion:
    my $iter= File::Whatever->new( $root );
    do {
        0   while  $iter->PushPath();
        while(  my $file= $iter->NextFile()  ) {
            doSomething( $file );
        }
    } while(  $iter->PopPath()  );

# Depth-first search w/ pruning w/o recursion:
    my $iter= File::Whatever->new( $root );
    do {
        while(  my $sub= $iter->PushPath()  ) {
            $iter->PopPath()   if  $sub =~ /debug/i;
        }
        while(  my $file= $iter->NextFile()  ) {
            doSomething( $file );
        }
    } while(  $iter->PopPath()  );

# The opposite of pruning:
# Only do things to files in directories named "debug"
    my $iter= File::Whatever->new( $root );
    do {
        if(  'debug' eq $iter->GetDirName()  ) {
            while(  my $file= $iter->NextFile()  ) {
                doSomething( $file );
            }
        }
    } while(  $iter->NextPath()  );

      [download]
      But I need to think about that a lot more before I'm sure that such makes sense or if I can make it better. (:

                      - tye
[reply]
[d/l]

In Section Seekers of Perl Wisdom