cutter has asked for the wisdom of the Perl Monks concerning the following question:

Hi, I am trying to figure out the right way to declare the $opt_* varable in Getopt::Std when use strict pragma. If I declare empty varables with my, they get passed to the script, but if I don't I get a "Global Symbol $opt_* requires explicit... error message. Commenting out use strict and it runs fine. Would loading the opt values into an array work? Thanks. 
use strict;


use Getopt::Std;

# my $opt_J="file";
# my $opt_f="file";
# my $opt_s="status";
# my $STATUS="stat";

getopts("J:f:s:");

if ($opt_J)
{
    print "Writing output to $opt_J \n";
}
if ($opt_f)
{
    print "Writing output== to $opt_f \n";
}
if ($opt_s)
{
    print "Status $opt_s \n";
}

#my $STATUS="AC";
#my $STATUS;

$STATUS=$opt_s;
print "Status is $STATUS \n";

[download]

Replies are listed 'Best First'.
Re: use strict with Getopt::Std
by rjray (Chaplain) on Mar 19, 2003 at 22:02 UTC

    This is a fairly common encounter for newer Perl programmers. As the previous reply points out, you can get around the scoping issues by using the vars pragma (or the our declaration in place of my).

    My suggestion is to avoid individual variables for the options completely. I never use the implicitly-sets-variable form of Getopts::Std or Getopts::Long. Instead, I always declare a hash table for the options (generally under a creative name like "%opts") and pass it by reference as the second parameter to the getopts call:

        getopts("J:f:s:", \%opts) or die "error message...";

    [download]

    This has several advantages: You still have a lexical variable, you're passing in an explicit reference to it which avoids the scoping problems; You can also add more options to your command-line logic without worrying about declaring new variables, and you can remove options without leaving declared-but-unused variables laying around.

    --rjray

[reply]
[d/l]

      still, for cutter to get this to work with strict, %opts will need to be declared first.

      something like:

      my %opts;
getopts( "J:f:s:", \%opts )
  or die "error message...";

## --or, all in one (shorter but not as clear)--

getopts( "J:f:s:", \my %opts )
  or die "...";

      [download]

      will have all the advantages you mentioned, and be strict compliant.

      ~Particle *accelerates*

[reply]
[d/l]
[select]

        My apologies-- I assumed that the need for declaring %opts would be obvious. However, that might have confused some of the newer Perl programmers. You are quite right about declaring it, of course.

        --rjray

[reply]
      One thing to note is that if you pre-define individual variables, you need to use "our" rather than "my": 
      use strict;
use Getopt::Std;
our($opt_a, $opt_b);
getopts('ab');

      [download]
      Mike
[reply]
[d/l]
Re: use strict with Getopt::Std
by larsen (Parson) on Mar 19, 2003 at 21:51 UTC
    With my you don't create a global, but a lexical. You want to 
    use vars qw/$opt_J ... and so on .../;

    [download]
    at the top of your program. This way, you'll tell your program that you're going to use those global variable names, and strict won't complain. I suggest to read Lexical scoping like a fox and Coping with Scoping. I think there will be a column by merlyn on this subject soon.
[reply]
[d/l]
[select]
      Thanks for the hints. I am just learning perl and trying to get my mind wrapped around the concept of scoping. This is what happens when you give a polsci major a computer.
[reply]
(jeffa) Re: use strict with Getopt::Std
by jeffa (Bishop) on Mar 19, 2003 at 22:01 UTC
    larsen is correct ... i just wanted to point out that you can also accomplish what you want with our: 
    our ($opt_J,$opt_f,$opt_s,$STATUS);
getopts("J:f:s:");

    [download]

    jeffa

    L-LL-L--L-LL-L--L-LL-L--
-R--R-RR-R--R-RR-R--R-RR
B--B--B--B--B--B--B--B--
H---H---H---H---H---H---
(the triplet paradiddle with high-hat)
[reply]
[d/l]

Back to Seekers of Perl Wisdom