First time using hashes

IPstacks has asked for the wisdom of the Perl Monks concerning the following question:

Hello brethren - I am just now learning perl and how to use hashes. I have written the following script:

#!/usr/bin/perl -w
use strict;

my %email_owners;
my @owners;
my @addys;

%email_owners = ('mike@foo.net' => 'Mike Foo',
  'jwtheis@smic.net' => 'Jim Theis',
  'happy@bobbarker.net' => 'Happy Gilmore');

@owners = values (%email_owners);
@addys = keys (%email_owners);

foreach (@owners) {
  print "Owner: $_\n";
    foreach (@addys) {
      print "E-mail: $_\n";
    }
}
[download]

What I am trying to accomplish is I want the output to be Owner: value then E-mail: key for each pair one by one. However when I run this script, it returns the Owner properly, but then it lists out the three keys that I have listed. I have reviewed my books and I'm not sure where I went wrong, can anyone help, please? Thanks much!

Comment on First time using hashes Download Code

Replies are listed 'Best First'.

Re: First time using hashes
by broquaint (Abbot) on Apr 01, 2003 at 14:50 UTC

%email_owners = (
  'mike@foo.net' => 'Mike Foo',
  'jwtheis@smic.net' => 'Jim Theis',
  'happy@bobbarker.net' => 'Happy Gilmore'
);

while(my($addy, $owner) = each %email_owners) {
  print "Owner: $owner\n";
  print "E-mail: $addy\n";
}

__output__

E-mail: jwtheis@smic.net
Owner: Happy Gilmore
E-mail: happy@bobbarker.net
Owner: Mike Foo
E-mail: mike@foo.net
[download]

print "Owner: $email_owners{$_}\nE-mail: $_\n"
  for keys %email_owners;
[download]

perldsc

_________ broquaint

[reply]
[d/l]
[select]

Re: First time using hashes
by jasonk (Parson) on Apr 01, 2003 at 14:52 UTC

#!/usr/bin/perl -w
use strict;

my %email_owners = ('mike@foo.net' => 'Mike Foo',
  'jwtheis@smic.net' => 'Jim Theis',
  'happy@bobbarker.net' => 'Happy Gilmore');

foreach (keys %email_owners) {
    print "Owner: $email_owners{$_}\n";
    print "E-mail: $_\n";
}
[download]

Because of the way you have the loop setup, you will go through the @addys array completely for every element in @owners, so by having three elements in @owners and three in @addys, you end up printing 9 emails. By splitting the hash into two arrays, you ended up disassociating the keys from the values.

If you really wanted to do it with two arrays, you could use something like this:

for(0 .. $#owners) {
    print "Owner: $owners[$_]\n";
    print "E-mail: $addys[$_]\n";
}
[download]

But then you really defeat the whole purpose of the hash.

We're not surrounded, we're in a target-rich environment!

[reply]
[d/l]
[select]

Re: First time using hashes
by Aragorn (Curate) on Apr 01, 2003 at 14:58 UTC

each

#!/usr/bin/perl -w

use strict;

my %email_owners;

%email_owners = (
    'mike@foo.net' => 'Mike Foo',
    'jwtheis@smic.net' => 'Jim Theis',
    'happy@bobbarker.net' => 'Happy Gilmore'
);

my ($owner, $addy);
while ( ($addy, $owner) = each %email_owners) {
  print "Owner: $owner\nEmail: $addy\n";
}
[download]

Arjen

[reply]
[d/l]
[select]

Re: First time using hashes
by Trimbach (Curate) on Apr 01, 2003 at 14:56 UTC

In general most of the time you don't need to break down the keys and values in a hash into separate arrays. If you want to list each owner and their address you might do this instead:

foreach my $addy(keys %email_owners) {
   print "Owner: $email_owners{$addy}\n";
   print "Address: $addy\n\n";
}
[download]

not

foreach my $addy(keys %email_addresses) {
   print "Owner: $email_addresses{$addy}\n";
   print "Address: $addy\n\n";
}
[download]