my %array_count;
foreach my $elem (@array) {
    $array_count{$elem}++;
}
foreach my $key (keys %array_count) {
    print "$key\n" if $array_count{$key} == 1;
}
[download]

The elements of the array become the keys of the hash, and the values of the hash are the number of times that the element is present in the array.

Arjen

    #!/usr/bin/perl -wl

    use strict;

    my @many = (1,4,2,3,2,1);


    my %count;

    $count{$_}++ for @many;

    my @once = grep {$count{$_} == 1} @many;


    print "@many";
    print "@once";

    __END__
    Prints:

    1 2 3 2 1
    4 3
[download]

--
John.

%seen = ();
@uniq = ();
foreach $item (@list) {
    unless ($seen{$item})  {
        # if we get here, we have not seen it before
        $seen{$item} = 1;
        push(@uniq, $item);
    }
}
[download]

Update: Inserted missed bracket spotted by Martymart

I tried two of these methods and they both worked for me... The method from zby was short and elegant looking, however the one from the cookbook gave me a result that more closely matched the input for some reason. Spotted a minor typo in that code though. Change line:unless ($seen{$item})to
unless ($seen{$item}){

Good answers to the question though,
Martymart

Here is my way to do it:

@hash{@array} = @array;
@onlyonce = keys %hash;
print "@onlyonce";
[download]

Although your solution uniqifies the elements of the array, it isn't possible to tell the number of times an element appears in the original array, which apparently is required.

Arjen

Hmm. I really can not find that requirement.

@h{@array}=undef; print for keys %h;