Setting up your %formdata hash would have been as simple as:

use CGI qw(param);
for (param()) {
  $formdata{$_} = param($_);
}
[download]

-- Randal L. Schwartz, Perl hacker
Be sure to read my standard disclaimer if this is a reply.

Let's play golf ;). Mine:

use CGI ':cgi-lib';
my %formdata = Vars;
[download]

---

If the above content is missing any vital points or you feel that any of the information is misleading, incorrect or irrelevant, please feel free to downvote the post. At the same time, please reply to this node or /msg me to inform me as to what is wrong with the post, so that I may update the node to the best of my ability.

Nope. Fails on multi-valued parameters, using that old ugly \0 convention. Mine just grabs the "first" one. (And I thought of that while I was typing mine in.)

-- Randal L. Schwartz, Perl hacker
Be sure to read my standard disclaimer if this is a reply.

A couple more pointers for you:

use POSIX;

my $date_for_logfile = strftime( "%e %B %C%y, %T", localtime);
[download]

$date_for_logfile is rediculously long, how about just $log_date instead? or $ts for timestamp? By the way, did you know that you can get a very nice generic timestamp by simply using:

my $ts = scalar localtime;
[download]

my $ip = '127.0.0.1';
print ip_error() unless check_ip($ENV{REMOTE_ADDR},$ip);
[download]

sub check_ip {
   my ($ip1,$ip2) = @_;
   return $ip1 eq $ip2;
}
[download]

sub ip_error {
   return header,
      start_html(
         -title => 'Error',
         -style => { 
            -code => q|body { font-family: "Verdana, Arial"; text-alig
+n: center; color: red }|,
         },
      ),
      b('Invalid ip-number'),
   ;
}
[download]

print ip_error() unless $ENV{REMOTE_ADDR} eq $ip;
[download]

Hope this helps, on the whole your script is nice, but you really should have cleaned it up a bit before you posted. As well as using strict and warnings, good indentation is a must, and until you develop your own style of 'proper' indentation, run your code through perltidy first. Here is a clue that you are not indenting properly: when you see two ending braces lined up with each other on two or more consecutive lines:

}
}
[download]

jeffa

L-LL-L--L-LL-L--L-LL-L--
-R--R-RR-R--R-RR-R--R-RR
B--B--B--B--B--B--B--B--
H---H---H---H---H---H---
(the triplet paradiddle with high-hat)

Ignoring the security concern about the IP address, here's a somewhat cleaner version of your code. With Perltidy and declaring variables, this only took a few minutes.

#!/usr/bin/perl -w
use strict;
use CGI qw(:standard);
use HTML::Entities;

my $myipnumber = "123.45.67.890";
my $full_path  = "/htdocs/data";
my $data_file  = "update.txt";

checkip();

my @days = (
  'Sunday',   'Monday', 'Tuesday', 'Wednesday',
  'Thursday', 'Friday', 'Saturday'
);
my @months = (
  'january', 'february', 'march',     'april',   'may',      'june',
  'july',    'august',   'september', 'october', 'november', 'december
+'
);
my ($sec, $min, $hour, $mday, $mon, $year, $wday) =(localtime(time))[0
+..6];
my $time = sprintf( "%02d:%02d:%02d", $hour, $min, $sec );
$year += 1900;
my $date_for_logfile = "$mday $months[$mon] $year, $time";

my %formdata = map { $_ => param($_) } param();
my @fieldsnames = keys %formdata;

open( RESULTS, ">$full_path/$data_file" ) || die "Couldn't open file: 
+$!\n";

my $results;
while (my ($key,$value) = each %formdata) {
  print RESULTS "$key=$value&";
  $results .= b($key)." - $value". br();
}
print RESULTS "updated=$date_for_logfile";
close(RESULTS);
encode_entities($results);

print 
  header(),
  start_html(-title => 'Results'),
  CGI::center( 
    b( 'Your Flash variables created $date_for_logfile :' ),
    br(),
    $results
  ),
  end_html;

exit;

sub checkip {
  unless ( $ENV{REMOTE_ADDR} eq $myipnumber ) {
    print header(),
      start_html(
        -title   => "Error!",
        -bgcolor => "white"
      ),
      CGI::center(
        font( {
          -face  => "Verdana, Arial",
          -color => "red",
          -size  => "3" },
          b("Invalid ip-number")
        )
      ),
      end_html;
    exit;
  }
}
[download]

Cheers,
Ovid

New address of my CGI Course.
Silence is Evil (feel free to copy and distribute widely - note copyright text)

About that time format, it's translated from dutch and I normally don't use capitals in the days.

I'll pay more attention to the formatting, use perltidy, be strict and pray to the almighty camel I will become a better monk in the near future ;)

teabag
chmod 666 *.* 'cause everyone should have the right to read and write!